Function eg_Particle_Emitter_Sort()
	Local eg_P.eg_Particle, ceg_P.eg_Particle, eg_PS.eg_ParticleSort
	
	;Partikel sortieren
	Local MinD#=0, MinDP.eg_Particle
	Repeat
		MinD#=0:MinDP.eg_Particle = Null
		
		ceg_P = First eg_Particle
		If ceg_P = Null Then Exit
		
		For eg_P = Each eg_Particle
			Local CurDist# = Math_Distance3(eg_P\fPos[0],eg_P\fPos[1],eg_P\fPos[2],EntityX(eg_Engine_Camera),EntityY(eg_Engine_Camera),EntityZ(eg_Engine_Camera))
			If CurDist > MinD#
				MinD = CurDist
				MinDP = eg_P
			EndIf
		Next
		If MinDP <> Null
			eg_PS = New eg_ParticleSort
			For I = 0 To 7
				eg_PS\fColor[I] = MinDP\fColor[I]
				If I <= 5 Then eg_PS\fDir[I] = MinDP\fDir[I]
				If I <= 3 Then eg_PS\fSize[I] = MinDP\fSize[I]
				If I <= 2 Then eg_PS\fPos[I] = MinDP\fPos[I]
				If I <= 1 Then eg_PS\fSpeed[I] = MinDP\fSpeed[I]
			Next
			eg_PS\eg_PE = MinDP\eg_PE
			eg_PS\iLifeTimeCur = MinDP\iLifeTimeCur
			eg_PS\iSpawnTime = MinDP\iSpawnTime
			Delete MinDP
		EndIf
	Forever
	Delete Each eg_Particle
	
	;Partikel sortiert wieder zurückgeben
	For eg_PS.eg_ParticleSort = Each eg_ParticleSort
		eg_P = New eg_Particle
		For I = 0 To 7
			eg_P\fColor[I] = eg_PS\fColor[I]
			If I <= 5 Then eg_P\fDir[I] = eg_PS\fDir[I]
			If I <= 3 Then eg_P\fSize[I] = eg_PS\fSize[I]
			If I <= 2 Then eg_P\fPos[I] = eg_PS\fPos[I]
			If I <= 1 Then eg_P\fSpeed[I] = eg_PS\fSpeed[I]
		Next
		eg_P\eg_PE = eg_PS\eg_PE
		eg_P\iLifeTimeCur = eg_PS\iLifeTimeCur
		eg_P\iSpawnTime = eg_PS\iSpawnTime
	Next
	Delete Each eg_ParticleSort
End Function

;Quick Sort
Function quickSort(list[100], anz)
	quick(list, 0, anz-1)
End Function

Function quick(list[100], lo, hi)
	Local i=lo, j=hi
	Local q=list[(lo+hi)/2]
	
	While i<=j
		While list[i]<q ;COMPARE(List[i], Q)
			i=i+1
		Wend
		
		While q<list[j] ;COMPARE(Q, List[i])
			j=j-1
		Wend
		
		If i<=j
			tmp=list[i] ;EXCHANGE(List[i], List[j])
			list[i]=list[j]
			list[j]=tmp
			
			i=i+1
			j=j-1
		EndIf
	Wend
	
	If lo<j
		quick(list, lo, j)
	EndIf
	
	If i<hi
		quick(list, i, hi)
	EndIf
End Function