;[Block]
Local Wuerfel1,Wuerfel2, Augensumme
Dim WuerfelSummenWahrscheinlichkeit#(11)
For Wuerfel1 = 1 To 6 ;Würfel 1 wird "gewürfelt"
	For Wuerfel2 = 1 To 6 ;Würfel 2 wird "gewürfelt"
		Augensumme=Wuerfel1+Wuerfel2
		WuerfelSummenWahrscheinlichkeit#(Augensumme-1)=WuerfelSummenWahrscheinlichkeit#(Augensumme-1)+1 
	Next
Next

Local i
For i=0 To 11
	WuerfelSummenWahrscheinlichkeit#(i)=WuerfelSummenWahrscheinlichkeit#(i)/36
	DebugLog WuerfelSummenWahrscheinlichkeit#(i)
Next
;[End Block]

Type FunktionsSpeicher
	Field GesPunkte#
End Type

;=========================================================================
Local Window      = CreateWindow("Auswertung",0,0,800,600,0,1)
Local timer		  = CreateTimer(60)

Local TXT_Set     = CreateTextField(20,20,100,25,Window)
Local TXT_Wuerfel = CreateTextField(120,20,50,25,Window)

Local BTM_Berechne= CreateButton("Berechne",170,20,100,25,Window)  
Local Treeview, TreeViewExists=0

Local EventQuelle

While Not KeyHit(1)
	If GetKey() = 27 Then End
	Select WaitEvent()
		Case $803
			End
			
			
		Case $401
			UpdateWindowMenu Window
			EventQuelle = EventSource()
			Select EventQuelle
				Case BTM_Berechne
					If TreeViewExists
						FreeGadget Treeview
					EndIf
					Treeview=CreateTreeView(20,50,500,400,Window)
					BerechneBestesSet(TextFieldText(TXT_Set),TextFieldText(TXT_Wuerfel),TreeViewRoot(Treeview))
					TreeViewExists=True
			End Select
			
	End Select
	
	WaitTimer(timer)
Wend

;=========================================================================
Function BerechneBestesSet$(Set$,WuerfelSumme,TreeHandle)
	;Diese Funktion berechnet die beste Zugöglichkeit und gibt anschließend das neue Kartenset (ohne die verdeckte Karte) als String aus.
	Local tempSet$, tempPWScore#
	Local bestSet$, bestPWScore#
	Local Wuerfel1,Wuerfel2
	
	Local SubHandle,Variante
	
	
	;Kann man die WürfelSumme mittels einer Karte darstellen?
	If WuerfelSumme<10
		If Instr(Set$,Str(WuerfelSumme))<>0 Then 
			tempSet$=Replace$(Set$,WuerfelSumme,"")
			
			Variante=Variante+1
			SubHandle = AddTreeViewNode("Variante "+Variante+")  "+tempSet$,TreeHandle)
			;Wenn man die WürfelSumme mittels einer Karte darstellen kann, wird mit dem Set ohne die umgedrehte Karte weitergerechnet.
			bestPWScore#=BewerteBestSubMove#(tempSet$,SubHandle)
			ModifyTreeViewNode SubHandle,"Variante "+Variante+")  "+tempSet$+" -> "+bestPWScore#
			DebugLog bestPWScore+"yyy"
			;Da hier in jedem Fall die erste Stellung analysiert wird, wird das Ergebnis der Simulation stehts als (vorerst) bestes Ergebnis erachtet.
			bestSet$=tempSet$
		EndIf
	EndIf
	
	
	;Kann man die WuerfelSumme mittels 2 Karten dastellen?
	For Wuerfel1=1 To WuerfelSumme
		If Instr(Set$,Str(Wuerfel1))<>0 Then
			Wuerfel2=WuerfelSumme-Wuerfel1
			If Wuerfel2>Wuerfel1 Then
				If Instr(Set$,Str(Wuerfel2))<>0 Then
					tempSet$=Replace$(Set$    ,Wuerfel1,"")
					tempSet$=Replace$(tempSet$,Wuerfel2,"")
					
					;Wenn man die WürfelSumme mittels zwei Karten darstellen kann, wird mit dem Set ohne die zwei umgedrehten Karten weitergerechnet.
					
					DebugLog "///////////////////////////////////////////////////////////////////////////////////"
					
					Variante=Variante+1
					SubHandle = AddTreeViewNode("Variante "+Variante+")  "+tempSet$,TreeHandle)
					tempPWScore#=BewerteBestSubMove#(tempSet$,SubHandle)
					ModifyTreeViewNode SubHandle,"Variante "+Variante+")  "+tempSet$+" -> "+tempPWScore#
					DebugLog tempSet$+": "+tempPWScore#
					
					;Wenn der 'PunkteWahrscheinlichkeitsScore', der bei der Simulation erreicht wurde besser ist, als der 'PunkteWahrscheinlichkeitsScore' von oben (eine Karte umgedreht) wird das Ergebnis (von oben) durch das neue (bessere) ersetzt.
					If tempPWScore#>bestPWScore#
						bestPWScore#=tempPWScore#
						bestSet$=tempSet$
					EndIf
					
				EndIf
			EndIf
		EndIf
	Next
	
	Return bestSet$
End Function

Function BewerteBestSubMove#(Set$,TreeHandle)
	Local WuerfelSumme
	Local Wuerfel1
	Local Wuerfel2
	
	Local EinZugMoeglich
	
	Local temp#
	Local tempSet$, BestSet$
	Local tempPunkte#, BestPunkte#
	
	Local Variante, SubHandle, UnterPunkt
	
	Select Set$
		Case ""
			ModifyTreeViewNode TreeHandle,"45"
			Return 45
			
			
		Case "1"
			ModifyTreeViewNode TreeHandle,"44"
			Return 44
			
		Default
			
			Local s.FunktionsSpeicher=New FunktionsSpeicher
			
			For WuerfelSumme=2 To 12
				UnterPunkt = AddTreeViewNode (WuerfelSumme+")",TreeHandle)
				
				EinZugMoeglich=0
				
				BestPunkte#=0
				tempPunkte#=0
				tempSet$=""
				Variante =0
				
				;Kann man die WürfelSumme mittels einer Karte darstellen?
				If WuerfelSumme<10
					If Instr(Set$,Str(WuerfelSumme))<>0 Then 
						EinZugMoeglich=1
						tempSet$=Replace$(Set$,WuerfelSumme,"")
						
						
						; // Variante 1
						Variante=Variante+1
						SubHandle = AddTreeViewNode("Variante "+Variante+") ["+tempSet$+"]",UnterPunkt)
						BestPunkte# = BewerteBestSubMove#(tempSet$,SubHandle)
						ModifyTreeViewNode SubHandle,"Variante "+Variante+") ["+tempSet$+"]  "+BestPunkte#
						
					EndIf
				EndIf
				
				
				;Kann man die WuerfelSumme mittels 2 Karten dastellen?
				For Wuerfel1=1 To WuerfelSumme
					If Instr(Set$,Str(Wuerfel1))<>0 Then
						Wuerfel2=WuerfelSumme-Wuerfel1
						If Wuerfel2>Wuerfel1 Then
							If Instr(Set$,Str(Wuerfel2))<>0 Then
								EinZugMoeglich=1
								tempSet$=Replace$(Set$    ,Wuerfel1,"")
								tempSet$=Replace$(tempSet$,Wuerfel2,"")
								
								
								; // Variante 2
								Variante=Variante+1
								SubHandle = AddTreeViewNode("Variante "+Variante+") ["+tempSet$+"]",UnterPunkt)
								tempPunkte# = BewerteBestSubMove#(tempSet$,SubHandle)
								ModifyTreeViewNode SubHandle,"Variante "+Variante+") ["+tempSet$+"]  "+tempPunkte#
								
								If tempPunkte#>BestPunkte#
									BestPunkte#=tempPunkte#
								EndIf
								
							EndIf
						EndIf
					EndIf
				Next
				
				
				If EinZugMoeglich=1 Then
					s\GesPunkte#=s\GesPunkte#+(WuerfelSummenWahrscheinlichkeit#(WuerfelSumme-1) * BestPunkte#)
					ModifyTreeViewNode UnterPunkt,WuerfelSumme+")  "+BestPunkte#
				Else
					s\GesPunkte#=s\GesPunkte#+WuerfelSummenWahrscheinlichkeit#(WuerfelSumme-1) * (SummeUmgedrehteZahlen(Set$))
					ModifyTreeViewNode UnterPunkt,WuerfelSumme+")  "+SummeUmgedrehteZahlen(Set$)
				EndIf
				
				
			Next
			
			
			UnterPunkt = AddTreeViewNode (s\GesPunkte#,TreeHandle)
			
			temp#=s\GesPunkte#
			
			Delete s.FunktionsSpeicher
			
			Return temp#
			
	End Select
	
End Function

Function SummeUmgedrehteZahlen(Set$)
	;Diese Funktion berechnet die Summe der nicht im zu bearbeitenden Set vorkommenden (umgedrehten) Kartenwerte.
	Local Karte,Summe
	
	For Karte=1 To 9
		If Not Instr(Set$,Karte) Then Summe=Summe+Karte
	Next
	
	Return Summe
End Function