;Stellt hilfreiche Erweiterungen für Blitz bereit.

;Konstanten #######################################################################################
;Blitz-Befehlsparameter ===========================================================================
Const CameraProjModeDisabled = 0, CameraProjModePerspective = 1, CameraProjModeOrthogonal = 2
Const CollisionMethodEllipsoid = 1, CollisionMethodPolygon = 2, CollisionMethodBox = 3
Const CollisionResponseNone = 1, CollisionResponseFullSliding = 2, CollisionResponseSliding = 3
Const EntityBlendNormal = 1, EntityBlendCombine = 2, EntityBlendAdditive = 3
Const EntityFxFullBright = 1, EntityFxVertexColors = 2, EntityFxFlatShaded = 4, EntityFxDisableFog = 8, EntityFxDisableCulling = 16, EntityFxEnableVertexAlpha = 32
Const EntityPickModeNone = 0, EntityPickModeRadius = 1, EntityPickModePolygon = 2, EntityPickModeBox = 3
Const FileTypeInvalid = 0, FileTypeFile = 1, FileTypeDirectory = 2
Const Graphics3DModeAutomatic = 0, Graphics3DModeFullscreen = 1, Graphics3DModeWindowed = 2, Graphics3DModeSizableWindowed = 3
Const MouseLeft = 1, MouseRight = 2, MouseMiddle = 3
Const SpriteViewModeFixedRoll = 1, SpriteViewModeFixed = 2, SpriteViewModeUnfixed = 3, SpriteViewModeFixedPitch = 4
Const TextureFilterColor = 1, TextureFilterAlpha = 2, TextureFilterMasked = 4, TextureFilterMipmapped = 8, TextureFilterClampU = 16, TextureFilterClampV = 32, TextureFilterReflection = 64, TextureFilterEnvironment = 128, TextureFilterVRAM = 256, TextureFilterHighColor = 512
;Tastenscancodes ----------------------------------------------------------------------------------
Const KeyEscape = 1, KeyF1 = 59, KeyF2 = 60, KeyF3 = 61, KeyF4 = 62, KeyF5 = 63, KeyF6 = 64, KeyF7 = 65, KeyF8 = 66, KeyF9 = 67
Const Key1 = 2, Key2 = 3, Key3 = 4, Key4 = 5, Key5 = 6, Key6 = 7, Key7 = 8, Key8 = 9, Key9 = 10, Key0 = 11, KeyBackspace = 14
Const KeyTab = 15, KeyQ = 16, KeyW = 17, KeyE = 18, KeyR = 19, KeyT = 20, KeyY = 21, KeyU = 22, KeyI = 23, KeyO = 24, KeyP = 25, KeyEnter = 28
Const KeyCapsLock = 58, KeyA = 30, KeyS = 31, KeyD = 32, KeyF = 33, KeyG = 34, KeyH = 35, KeyJ = 36, KeyK = 37, KeyL = 38
Const KeyShiftLeft = 42, KeyZ = 44, KeyX = 45, KeyC = 46, KeyV = 47, KeyB = 48, KeyN = 49, KeyM = 50, KeyShiftRight = 54
Const KeyCtrlLeft = 29, KeyWinLeft = 219, KeyAlt = 56, KeySpace = 57, KeyAltGr = 184, KeyWinRight = 220, KeyContextMenu = 221, KeyCtrlRight = 157
Const KeyPrint = 183, KeyRoll = 70, KeyPause = 197
Const KeyIns = 210, KeyHome = 199, KeyPageUp = 201
Const KeyDel = 211, KeyEnd = 207, KeyPageDown = 209
Const KeyArrowUp = 200
Const KeyArrowLeft = 203, KeyArrowDown = 208, KeyArrowRight = 205
Const KeyNumLock = 69, KeyNumDivide = 181, KeyNumMultiply = 55, KeyNumMinus = 74
Const KeyNum7 = 71, KeyNum8 = 72, KeyNum9 = 73, KeyNumPlus = 78
Const KeyNum4 = 75, KeyNum5 = 76, KeyNum6 = 77
Const KeyNum1 = 79, KeyNum2 = 80, KeyNum3 = 81, KeyNumEnter = 156
Const KeyNum0 = 82, KeyNumSeperator = 83

;Funktionen #######################################################################################
;Mathematisches ===================================================================================
;Not A Number -------------------------------------------------------------------------------------
Global NaN# = Sqr(-1)
;Gibt den ersten Wert zurück wenn true, sonst den zweiten -----------------------------------------
Function IIf#(Condition, IfTrue#, IfFalse#)
    If Condition Then
        Return IfTrue
    Else
        Return IfFalse
    End If
End Function
;Prüft, ob Zahl zwischen beiden Grenzen -----------------------------------------------------------
Function IsBetween(Value#, LowerBound#, UpperBound#)
    Return Value >= LowerBound And Value <= UpperBound
End Function
;Maximum von zwei Zahlen --------------------------------------------------------------------------
Function Max#(A#, B#)
    If A > B Then
        Return A
    Else
        Return B
    End If
End Function
;Minimum von zwei Zahlen --------------------------------------------------------------------------
Function Min#(A#, B#)
    If A < B Then
        Return A
    Else
        Return B
    End If
End Function
;Liefert Zahl zwischen beiden Grenzen -------------------------------------------------------------
Function Clamp#(Value#, LowerBound#, UpperBound#)
    If Value < LowerBound Then
        Return LowerBound
    Else If Value > UpperBound Then
        Return UpperBound
    Else
        Return Value
    End If
End Function
;Schneidet den Dezimalteil ab ---------------------------------------------------------------------
Function Cut#(A#, Decimals)
    Local Pow = 10 ^ Decimals
    Return Float(Int(A * Pow)) / Pow
End Function
;Wandelt einen Wert zwischen 0-255 in einen zwischen 0.0-1.0 um -----------------------------------
Function ByteToFloat#(Value)
    Return Value / 255.0
End Function
;Wandelt einen Wert zwischen 0.0-1.0 in einen zwischen 0-255 um -----------------------------------
Function FloatToByte(Value#)
    Return Value * 255
End Function
;Überprüft, ob radiale Objekte kollidieren --------------------------------------------------------
Function CheckCollision(SourceEntity, SourceRadius#, TargetEntity, TargetRadius#)
    Return EntityDistance(SourceEntity, TargetEntity) < SourceRadius + TargetRadius
End Function
;Liefert Alpha-, Rot-, Grün- und Blauanteil des übergebenen ARGB-Codes ----------------------------
Dim Argb(3)
Function GetArgbComponents(Value)
    Argb(0) = (Value And $FF000000) / $1000000
    Argb(1) = (Value And $FF0000) / $10000
    Argb(2) = (Value And $FF00) / $100
    Argb(3) = Value And $FF
End Function
;Liefert den Argb-Farbcode aus den Werten im Argb-Array -------------------------------------------
Function GetArgbValue()
    Return Argb(0) * $1000000 + Argb(1) * $10000 + Argb(2) * $100 + Argb(3)
End Function
;Erstellt Zufallslisten ohne Dubletten zwischen Minimum und Maximum -------------------------------
Dim RandomTemp(0)
Dim RandomList(0)
Function CreateRandomList(Count, Minimum, Maximum)
    If Count - 1 > Maximum - Minimum Then
        RuntimeError("Can't make " + Count + " different numbers with only " + (Maximum - Minimum) + " choices.")
    Else
        ;Liste mit Zahlen der Reihe nach erstellen
        Local RandomTempLength = Count - 1
        Dim RandomTemp(RandomTempLength)
        For i = 0 To RandomTempLength
            RandomTemp(i) = i + Minimum
        Next
        
        ;Zufällige Zahlenliste daraus erstellen
        Dim RandomList(RandomTempLength)
        Local PickedIndex
        For i = 0 To Count - 1
            PickedIndex = Rand(0, RandomTempLength)
            RandomList(i) = RandomTemp(PickedIndex)
            RandomTemp(PickedIndex) = RandomTemp(RandomTempLength)
            RandomTempLength = RandomTempLength - 1
        Next
    End If
End Function

;String-Funktionen ================================================================================
;Zeilenumbruch ------------------------------------------------------------------------------------
Global LF$ = Chr(13)
;Teilt Zeichenketten auf --------------------------------------------------------------------------
Global SplitCount
Dim SplitString$(0)
Function Split(Value$, SplitChar$)
	SplitCount = 0
	For i = 1 To Len(Value)
		Local CurChar$ = Mid(Value, i, 1)
		If CurChar = SplitChar Then SplitCount = SplitCount + 1
	Next
	Dim SplitString$(SplitCount)
	Local CurrentSplit
	For i = 1 To Len(Value)
		CurChar$ = Mid(Value, i, 1)
		If CurChar <> SplitChar Then
			SplitString(CurrentSplit) = SplitString(CurrentSplit) + CurChar
		Else
			CurrentSplit = CurrentSplit + 1
		End If
	Next
End Function
;Fügt Nullen dem Nachkomma- oder Vorkommaanteil hinzu ---------------------------------------------
Function FitNumber$(A#, PostFill, PreFill = -1, PreFillChar$ = " ")
    Split(A#, ".")
    While Len(SplitString(1)) < PostFill
        SplitString(1) = SplitString(1) + "0"
    Wend
    While Len(SplitString(0)) < PreFill
        SplitString(0) = PreFillChar + SplitString(0)
    Wend
    Return SplitString(0) + "." + SplitString(1)
End Function
;Entfernt unnötige Endnullen bei Kommazahlen ------------------------------------------------------
Function TrimNumber$(A#)
    If Int(A) = A Then
        Return Int(A)
    Else
        Return A
    End If
End Function
;Schreibt einen null-terminierten String ----------------------------------------------------------
Function Write0String(Stream, Value$)
    For i = 1 To Len(Value)
        WriteByte(Stream, Asc(Mid(Value, i, 1)))
    Next
    WriteByte(Stream, 0)
End Function
;Liest einen null-terminierten String -------------------------------------------------------------
Function Read0String$(Stream)
    Local Value$
    Repeat
        i = ReadByte(Stream)
        If i = 0 Then
            Return Value
        Else
            Value = Value + Chr(i)
        End If
    Forever
End Function
;Zeichnet mehrzeiligen Text -----------------------------------------------------------------------
Function TextMultiline(X, Y, Value$, CentreX = False, CentreY = False, Spacing = 0)
	Local CentreHeight
	Split(Value, LF)
	If CentreY Then CentreHeight = (FontHeight() * (SplitCount + 1) / 2) + (Spacing * SplitCount / 2)
	For i = 0 To SplitCount
		Text X, Y + i * FontHeight() + Spacing * i - CentreHeight, SplitString(i), CentreX
	Next
End Function
;Liefert den einsbasierten Index des ersten Vorkommens des Zeichens von hinten aus ----------------
Function InstrR(String_$, Find$, From = -1, To_ = 1)
    If From = -1 Then
        From = Len(String_)
    End If
    If From > To_ Then
        For i = From To To_ Step -1
            If Mid(String_, i, 1) = Find Then
                Return i
            End If
        Next
    End If
    Return 0
End Function

;Eingabe ==========================================================================================
;Überprüft, ob die Maus im Rechteck ist -----------------------------------------------------------
Function MouseInRect(X, Y, Width, Height)
	Return (MseX >= X And MseX < X + Width) And (MseY >= Y And MseY < Y + Height)
End Function

;Dateisystem ======================================================================================
;Kombiniert Verzeichnisnamen oder Dateinamen ------------------------------------------------------
Function CombinePath$(Path1$, Path2$)
    Local CombinedPath$
    If Right(Path1, 1) = "\" Then
        CombinedPath = Path1 + Path2
    Else
        CombinedPath = Path1 + "\" + Path2
    End If
    Return CombinedPath
End Function
;Liefert die Anzahl der Dateien in einem Verzeichnis zurück ---------------------------------------
Function GetFileCount(DirectoryPath$)
    Local FileCount = 0
    
    Local FoundObject$
    Local Directory = ReadDir(DirectoryPath)
    Repeat
        FoundObject = NextFile(Directory)
        If FoundObject = "" Then
            Exit
        Else
            If FileType(CombinePath(DirectoryPath, FoundObject)) = FileTypeFile Then
                FileCount = FileCount + 1
            End If
        End If
    Forever
    CloseDir(Directory)
    
    Return FileCount
End Function
;Liefert die Anzahl der Dateien in einem Ordner zurück --------------------------------------------
Function GetDirectoryCount(DirectoryPath$)
    Local DirectoryCount = 0
    
    Local FoundObject$
    Local Directory = ReadDir(DirectoryPath)
    Repeat
        FoundObject = NextFile(Directory)
        If FoundObject = "" Then
            Exit
        Else
            If FoundObject <> "." And FoundObject <> ".." And FileType(FoundObject) = FileTypeDirectory Then
                DirectoryCount = DirectoryCount + 1
            End If
        End If
    Forever
    CloseDir(Directory)
    
    Return DirectoryCount
End Function
;Liefert einen zufälligen Dateinamen aus dem übergebenen Verzeichnis zurück -----------------------
Function GetRandomFilename$(Path$)
    ;Zufallszahl für Dateinummer berechnen
    Local FileCount = GetFileCount(Path)
    Local FileNumber = Rand(1, FileCount)
    
    ;Dateinamen der Datei mit der berechneten Nummer zurückgeben
    Local CurrentFile = 0
    Local Directory = ReadDir(Path)
    Local FoundObject$
    Repeat
        FoundObject = NextFile(Directory)
        If FileType(Path + FoundObject) = FileTypeFile Then
            CurrentFile = CurrentFile + 1
        End If
    Until CurrentFile = FileNumber
    CloseDir(Directory)
    
    Return FoundObject
End Function
;Extrahiert den Dateinamen aus einem Pfad ---------------------------------------------------------
Function GetFilename$(Path$)
    Local SeperatorIndex = InstrR(Path, "\")
    Return Mid(Path, SeperatorIndex + 1, Len(Path) - SeperatorIndex)
End Function
;Extrahiert den Dateinamen ohne Dateierweiterung aus einem Pfad -----------------------------------
Function GetFilenameWithoutExtension$(Path$)
    Local Filename$ = GetFilename(Path)
    Return Left(Filename, InstrR(Filename, ".") - 1) 
End Function

;Bildmanipulation =================================================================================
;Liefert den Inhalt des aktuellen Bildschirms als Bild zurück -------------------------------------
Function GetCurrentScreen()
    Local Screen = CreateImage(ResWidth, ResHeight)
    CopyRect(0, 0, ResWidth, ResHeight, 0, 0, BackBuffer(), ImageBuffer(Screen))
    Return Screen
End Function
;Verdunkelt oder verhellert das Bild um den angegebenen Betrag ------------------------------------
Function ImageGamma(Image, Amount#, Safe = True)
    Local Buffer = ImageBuffer(Image)
    LockBuffer(Buffer)
    
    ;Entweder sicher (ohne Überlauf) berechnen oder schnell mit Gefahr von falschen Farben
    If Safe Then
        For y = 0 To ImageHeight(Image) - 1
            For x = 0 To ImageWidth(Image) - 1
                GetArgbComponents(ReadPixelFast(x, y, Buffer))
                Argb(1) = Min(Argb(1) * Amount, 255)
                Argb(2) = Min(Argb(2) * Amount, 255)
                Argb(3) = Min(Argb(3) * Amount, 255)
                WritePixelFast(x, y, GetArgbValue(), Buffer)
            Next
        Next
    Else
        For y = 0 To ImageHeight(Image) - 1
            For x = 0 To ImageWidth(Image) - 1
                GetArgbComponents(ReadPixelFast(x, y, Buffer))
                Argb(1) = Argb(1) * Amount
                Argb(2) = Argb(2) * Amount
                Argb(3) = Argb(3) * Amount
                WritePixelFast(x, y, GetArgbValue(), Buffer)
            Next
        Next
    End If
    
    UnlockBuffer(Buffer)
End Function

MeshesIntersect

Text

Instr

Function WurzelDistanz:Float(x1:Float,y1:Float,x2:Float,y2:Float)
     Return Sqr((x2-x1)*(x2-x1)+(y2-y1)*(y2-y1))
End Function

Function Pixelweg:Float(x1:Float, y1:Float, x2:Float, y2:Float)
     Return Abs(x2-x1)+Abs(y2-y1)
End Function

Local RandomTemp[Count]

Local RandomTempLength = Count - 1
Local RandomTemp[RandomTempLength]