BeginnerProblem Menu Steuerung

Übersicht BlitzBasic Beginners-Corner

Neue Antwort erstellen

Vinz

Betreff: BeginnerProblem Menu Steuerung

 BeitragDi, März 15, 2005 12:12
Antworten mit Zitat
Benutzer-Profile anzeigen
So ganz kurz, Ich verusche eine Menusteuerung zu schaffen in der ein Pfeil durch cursortasten gesteuert werden soll, durch 3 Positionen aber ich bekomme nicht raus wie, PLs, help. Bild+Code:

Bild: http://www.f4k0rg077.space4fre...cs/fff.JPG

BlitzBasic: [AUSKLAPPEN] 
;###############################
;#########/---------\###########
;#########|Menu_Tank|###########
;#########\---------/###########
;###############################
Graphics 640, 480, 32, 2
AppTitle \"Tankgame\", \"Are you serious?\"
Global x=1

MenuHG = LoadImage(\"Menu_HGB1.JPG\") ;HGB 640, 480
Pfeil = LoadAnimImage(\"Pfeil1and2.bmp\", 45, 24, 0, 1) ;Pfeil 90, 24
MaskImage Pfeil ,255, 0, 255
DrawImage MenuHG ,0, 0
DrawImage Pfeil ,390, 227, 0

While Not KeyHit (x)

	Color 50,50,50
	Text 240, 230, \"Game-Start 1Player\" 
	Text 240, 250, \"Game-Start 2Player\"
	Text 250, 300, \"Help - Tank-Game\"
	
	pos_b=390
	
WaitKey
	
		If Not KeyHit=208 Or KeyHit=200 Then sit_a=1
		If KeyHit(208) And pos_h=227 Then sit_a=2
		If KeyHit(200) And pos_h=227 Then sit_a=3
		If KeyHit(208) And pos_h=247 Then sit_a=4
		If KeyHit(200) And pos_h=247 Then sit_a=5
		If KeyHit(208) And pos_h=297 Then sit_a=6
		If KeyHit(200) And pos_h=297 Then sit_a=7
		
			Select sit_a

			Case sit_a=1 Cls:DrawImage MenuHG ,0, 0:pos_h=227;1-1 (nix)
			Case sit_a=2 Cls:DrawImage MenuHG ,0, 0:pos_h=247;1-2 (runter)
			Case sit_a=3 Cls:DrawImage MenuHG ,0, 0:pos_h=297;1-3 (hoch)
			Case sit_a=4 Cls:DrawImage MenuHG ,0, 0:pos_h=297;2-3 (runter)
			Case sit_a=5 Cls:DrawImage MenuHG ,0, 0:pos_h=227;2-1 (hoch)
			Case sit_a=6 Cls:DrawImage MenuHG ,0, 0:pos_h=227;3-1 (runter)
			Case sit_a=7 Cls:DrawImage MenuHG ,0, 0:pos_h=247;3-2 (hoch)

			End Select
		
				Print \"sit_a= \"+sit_a
				DrawImage Pfeil ,pos_b, pos_h, 0

Wend 
End
;###############################
;##########/-------\############
;##########|The-End|############
;##########\-------/############
;###############################
[/code]

Vinz

Betreff: .

 BeitragDi, März 15, 2005 12:15
Antworten mit Zitat
Benutzer-Profile anzeigen
Huch ich glaub das Bild haett ich besser aufloesen koennen, egal ich glaub der Sinn ist verstaendlich XD
 

Mogon

 BeitragDi, März 15, 2005 15:37
Antworten mit Zitat
Benutzer-Profile anzeigen
Ich hab das in meinem Spiel so gelöst:

ausgewaehlt = 1 ; Die Var in der der gerade angewählte Menüeintrag gespeichert ist

If keyhit(28) (;wenn pfeil runter gedrückt wird) then ausgewaehlt = ausgewaehlt + 1

Select ausgewaehlt ; Hier wird dann der Pfeil gezeichnet
case 1 then drawimage pfeil,400,300+50*ausgewaehlt
usw....
end select

Noch Fragen?

Vinz

Betreff: hmmm...

 BeitragDi, März 15, 2005 16:00
Antworten mit Zitat
Benutzer-Profile anzeigen
Stimmt das ist ein ganz anderer loesungsweg, ich glaube nicht das ich jemals versucht haette das so zu loesen. Danke ich versuchs jetzt damit. Ich glaube das spaart ne menge quelltext ein.

Bigmichi

 BeitragDi, März 15, 2005 16:10
Antworten mit Zitat
Benutzer-Profile anzeigen
hab dein Prob gelesen udn hab mal ein BasicMenu gebastelt =)

https://www.blitzforum.de/view...562#110562

Vinz

Betreff: Mist

 BeitragDi, März 15, 2005 16:31
Antworten mit Zitat
Benutzer-Profile anzeigen
Hab keinen zugriff darauf, die Seite ist gesperrt fuer mich, Shit.
kannst du Quelltext schreiben dann kann ich im BB compiliern und ausprobiern.

Downloads sind fuer mich hier gesperrt SRY.

Vinz

Betreff: SO

 BeitragDi, März 15, 2005 16:38
Antworten mit Zitat
Benutzer-Profile anzeigen
Habe Mogons Weg versucht aber der Zaehler funktioniert nicht richtig der zaehlt nicht weiter als einmal+ oder -,ich schaetze mal ich muss den Wert fuer die anzahl der keyhits irgendwo zwischenspeichern, oder?

Bigmichi

 BeitragDi, März 15, 2005 16:39
Antworten mit Zitat
Benutzer-Profile anzeigen
der Code hängt unten aber du solltest dir die rgafiken Speichern und zwar machst du ein Ordner in den du den Text da machst udn dan ein Ordner in den Ordner der GFX heißt... und dort die Bilder reinmachen



http://server.future-coding.de...GFX/BG.jpg
http://server.future-coding.de.../Start.png
http://server.future-coding.de...redits.png
http://server.future-coding.de...tionen.png
http://server.future-coding.de...X/Exit.png
http://server.future-coding.de...Rahmen.png




BlitzBasic: [AUSKLAPPEN] 

Global GX = 1024, GY = 768

Graphics3D GX,GY,16,2
SetBuffer BackBuffer()


Global GameStatus = 1 ;1 = Menu | 2 = SpielMenu | 3 = Game | 3 = Ende
Global MausX,MausY,MausHit1

Global MenuPunkt = 1

Global GrafikBG, GrafikStart, GrafikOptionen, GrafikCredits, GrafikExit, GrafikRahmen

Global Winkel1,Winkel2


BilderLaden()


While GameStatus < 4


	Update()
	
	Flip
	Cls
Wend
End




Function Update()

	Input()

	
	Select GameStatus
		Case 1
			UpdateMenu()
		Case 2
			UpdateMenu()  ;SpielMenu
		Case 3
			UpdateGame()
	End Select
	

End Function


Function Input()

	UpdateTastatur()
	UpdateMaus()
	
	FlushKeys()
End Function


Function UpdateMaus()

	MausX = MouseX()
	MausY = MouseY()
	MausHit = MouseHit(1)
	
	If MausX > (GX/2)-128 And MausX < (GX/2)+128 Then
		If MausY > (GY/2)-256 And MausY < (GY/2)-128 Then MenuPunkt = 1
		If MausY > (GY/2)-128 And MausY < (GY/2) Then MenuPunkt = 2
		If MausY > (GY/2) And MausY < (GY/2)+128 Then MenuPunkt = 3
		If MausY > (GY/2)+128 And MausY < (GY/2)+256 Then MenuPunkt = 4
	End If
	
End Function


Function UpdateTastatur()

	
	If KeyHit(1) Then
		If GameStatus = 2 Then GameStatus = 3 ElseIf GameStatus = 3 GameStatus = 2
	End If
	
	If KeyHit(200) Then	MenuPunkt = MenuPunkt - 1
	If KeyHit(208) Then MenuPunkt = MenuPunkt + 1
	
	
	If MenuPunkt < 1 Then MenuPunkt = 4
	If MenuPunkt > 4 Then	MenuPunkt = 1
	
	
	If KeyHit(28) Then 
		Select MenuPunkt
			Case 1
				GameStatus = 3
			Case 4
				GameStatus = 4
		End Select
	End If
	

End Function


Function UpdateMenu()


	DrawImage GrafikBG,0,0
	
	Select MenuPunkt
		Case 1
			DrawImage GrafikRahmen,(GX/2),(GY/2)-192
		Case 2
			DrawImage GrafikRahmen,(GX/2),(GY/2)-64
		Case 3
			DrawImage GrafikRahmen,(GX/2),(GY/2)+64
		Case 4
			DrawImage GrafikRahmen,(GX/2),(GY/2)+192
	End Select
	
	DrawImage GrafikStart,(GX/2),(GY/2)-192
	DrawImage GrafikOptionen,(GX/2),(GY/2)-64
	DrawImage GrafikCredits,(GX/2),(GY/2)+64
	DrawImage GrafikExit,(GX/2),(GY/2)+192


End Function


Function UpdateGame()

	Winkel1=(Winkel1+5) Mod 360
	Winkel2=(Winkel2+2) Mod 360
	
	X=(GX/2)+Cos(Winkel1)*200+Cos(Winkel2)*120
	Y=(GY/2)+Sin(Winkel1)*160+Sin(Winkel2)*80

 Oval X-10,Y-10,20,20,1

End Function





Function BilderLaden()


	GrafikBG = LoadImage(\"GFX/BG.jpg\")
	
	AutoMidHandle True
	GrafikStart = LoadImage(\"GFX/Start.png\")
	ScaleImage GrafikStart,0.5,0.5
	GrafikCredits = LoadImage(\"GFX/Credits.png\")
	ScaleImage GrafikCredits,0.5,0.5
	GrafikOptionen = LoadImage(\"GFX/Optionen.png\")
	ScaleImage GrafikOptionen,0.5,0.5
	GrafikExit = LoadImage(\"GFX/Exit.png\")
	ScaleImage GrafikExit,0.5,0.5
	
	GrafikRahmen = LoadImage(\"GFX/Rahmen.png\")
	ScaleImage GrafikRahmen,0.7,1.3
	
	AutoMidHandle False
	
End Function

Vinz

Betreff: .

 BeitragDi, März 15, 2005 17:21
Antworten mit Zitat
Benutzer-Profile anzeigen
Thanks alot.

WoW das klapt sogar.

Neue Antwort erstellen


Übersicht BlitzBasic Beginners-Corner

Nach Oben

Gehe zu:

Powered by phpBB © 2001 - 2006, phpBB Group