;=========================================================================
; Darstellung:
;	X-Achse:	Türen
;	Y-Achse:	Tage
;	Prinzessin:	blau
;	Prinz:		rot
;	Ziel:		grün
;	Ihr seht sowohl den Verlauf der Prinzessin wie auch den des Prinzen
;-------------------------------------------------------------------------
; Ziel:
;	Schafft es, in der gegeben Anzahl Tage das Ziel zu erreichen, ohne
;	dem Prinzen zu Begegnen.
;-------------------------------------------------------------------------
; Steuerung:
;	Sucht euch zu Beginn ein freies Zimmer mit den Pfeiltasten links und
;	rechts, woraufhin ihr mit der Leertaste das Abenteuer starten könnt.
;	Nach jeder Nacht dürft ihr ein neues Zimmer links oder rechts vom
;	letzten aufsuchen.
;	Sollte es zur Begegnung mit dem Prinzen kommen, startet das Spiel neu.
;;=========================================================================



;=========================================================================
; Die Anzahl an türen (von 3 an aufwärts)
Const N%		= 5
;=========================================================================


; Anzahl Nächte, die das Spiel höchstens dauern wird
Const D_MAX%	= (N-2) *2 +2

; Grösse eines Feldes in Pixel
; Diese lustige Deklaration sorgt dafür, dass für kleine N ausreichend grosse
; Felder gezeichnet werden (BB-Fenster dürfen nicht zu klein sein) und für
; grosse N eher kleine Felder gezeichnet werden
Const FIELD_SIZE%	= 44*(N=3) +34*(N=4) +27*(N=5) +22*(N=6) +19*(N=7) +17*(N=8) +16*(N>8)

Const FIELD_FREE%	= 0
Const FIELD_LOCKED%	= 1
Const FIELD_TARGET%	= 2
Const FIELD_FIGURE%	= 3

; Finite State Machine Zeug
Const STATE_START%		= 0
Const STATE_PLAYING%	= 1
Local state%

; Keycodes benennen zwecks lesbarerem Code
Const KEY_ESCAPE%	= 1
Const KEY_LEFT%		= 203
Const KEY_RIGHT%	= 205
Const KEY_START%	= 57

;-------------------------------------------------------------------------
; Grafikmodus setzen
Const GF_WIDTH%		= N *FIELD_SIZE
Const GF_HEIGHT%	= D_MAX *FIELD_SIZE
Graphics(GF_WIDTH, GF_HEIGHT, 0, 2)
SetBuffer BackBuffer()
Local timer% = CreateTimer(20)

; Spiel-Variablen
Local posi%, posj%=-1
Dim map(N,D_MAX)

; Spielfeld füllen
; Hier wird der Pfad des Prinzen festgelegt...
Local i%, j%, t%
For j = 0 To D_MAX-1
	; ... genau hier:
	If j < D_MAX-1 Then
		t = j
		If t=0 Then t=1
		If t>N-2 Then t=2*N-3-t
		If t<1 Then t=1
	EndIf
	For i = 0 To N-1
		If j = D_MAX-1 Then
			map(i,j) = FIELD_TARGET
		ElseIf j < D_MAX-1
			If t=i Then
				map(i,j) = FIELD_LOCKED
			EndIf
		EndIf
	Next
Next

; Spieeeel
Local lr%, npos%, txt$
While Not KeyDown(KEY_ESCAPE)
	; Figur bewegen
	lr = KeyHit(KEY_RIGHT) -KeyHit(KEY_LEFT)
	npos = posi +lr						; theoretisch neue Position
	If npos < 0 Then npos = posi		; links / rechts begrenzen
	If npos > N-1 Then npos = posi
	
	; zu Beginn: Startfeld wählen
	If state = STATE_START Then
		txt = "STARTFELD WÄHLEN"
		posi = npos
		If KeyHit(KEY_START)=True And map(posi, 0)=FIELD_FREE Then
			state = STATE_PLAYING
			posj = 0
		EndIf
	; danach: Figur bewegen
	ElseIf state = STATE_PLAYING Then
		txt = "BEWEGEN"
		; Erreichen eines freien Feldes
		If npos <> posi Then
			map(posi, posj) = FIELD_FIGURE
			posi = npos
			posj = posj +1
		EndIf
		; "Kollision" mit dem Prinzen
		If map(posi, posj) = FIELD_LOCKED Then
			posi = 0
			posj = -1
			state = STATE_START
			For j = 0 To D_MAX-1
				For i = 0 To N-1
					If map(i,j) = FIELD_FIGURE Then
						map(i,j) = FIELD_FREE
					EndIf
				Next
			Next 
		EndIf
	EndIf
	
	Cls
	; Spielfeld zeichnen
	For j = 0 To D_MAX-1
		For i = 0 To N-1
			Select map(i,j)
				; Ziel
				Case FIELD_TARGET
					Color(0,128,0)
					Rect(i*FIELD_SIZE, j*FIELD_SIZE, FIELD_SIZE, FIELD_SIZE)
				; Prinz
				Case FIELD_LOCKED
					; Nächste Nacht
					If j=(posj+1) Then
						Color(128,0,0)
						Rect(i*FIELD_SIZE, j*FIELD_SIZE, FIELD_SIZE, FIELD_SIZE)
					; Pfad
					ElseIf j<=posj Then
						Color(128,96,96)
						Rect(i*FIELD_SIZE, j*FIELD_SIZE, FIELD_SIZE, FIELD_SIZE)
					EndIf
				; Prinzessin (nur Pfad)
				Case FIELD_FIGURE
					Color(96,128,160)
					Oval(i*FIELD_SIZE +2, j*FIELD_SIZE +2, FIELD_SIZE -4, FIELD_SIZE -4)
			End Select
		Next
	Next
	
	; Aktuelle Prinzessinenposition
	Color(0,128,255)
	Oval(posi*FIELD_SIZE+2, (posj +(posj=-1))*FIELD_SIZE+2, FIELD_SIZE-4, FIELD_SIZE-4)
	
	; Anweisung
	Color(255,255,255)
	Text GF_WIDTH /2, GF_HEIGHT -FIELD_SIZE /2, txt, True, True
	
	WaitTimer(timer)
	Flip 0
Wend
End