Const GRAPHICS_X_OFFSET = 50 ; [px]
Const GRAPHICS_Y_OFFSET = 600 - 50; [px]
Const GRAPHICS_X_SCALE# = 80.0 ; [px/m]
Const GRAPHICS_Y_SCALE# = -80.0 ; [px/m]

Type TVector
	Field X#
	Field Y#
End Type

Function CreateVector.TVector(X#, Y#)
	Local V.TVector = New TVector
	SetXY(V, X, Y)
	Return V
End Function

; R = V
Function CopyVector(R.TVector, V.TVector)
	R\X = V\X
	R\Y = V\Y
End Function

; V = (X, Y)
Function SetXY(V.TVector, X#, Y#)
	V\X = X
	V\Y = Y
End Function

; R = A + B
Function AddVector(R.TVector, A.TVector, B.TVector)
	R\X = A\X + B\X
	R\Y = A\Y + B\Y
End Function

; R = A - B
Function SubstractVector(R.TVector, A.TVector, B.TVector)
	R\X = A\X - B\X
	R\Y = A\Y - B\Y
End Function

; R = S*V
Function ScaleVector(R.TVector, V.TVector, S#)
	R\X = S*V\X
	R\Y = S*V\Y
End Function

; |V|
Function VectorLength#(V.TVector)
	Return Sqr(V\X*V\X + V\Y*V\Y) 
End Function

Function DrawVector(V.TVector)
	Local X% = GRAPHICS_X_OFFSET + GRAPHICS_X_SCALE*V\X
	Local Y% = GRAPHICS_Y_OFFSET + GRAPHICS_Y_SCALE*V\Y

	Oval(X - 2, Y - 2, 5, 5)
End Function

; Eingangswerte
Global Mass# = 0.65 ; [kg]
Global ImpactDuration# = 0.25 ; [s]
Global ImpactForce.TVector = CreateVector(10.0, 25.0) ; [N = kg*m/s²]
Global GravityAcceleration.TVector = CreateVector(0.0, -9.81) ; [m/s²]
Global GravityForce.TVector = New TVector
       ScaleVector(GravityForce, GravityAcceleration, Mass) ; [m*kg/s²]
Global Velocity0.TVector = CreateVector(0.0, 0.0) ; [m/s]
Global Position0.TVector = CreateVector(0.0, 1.8) ; [m]

; Zu berechnende Variablen
Global Velocity.TVector = New TVector
Global Position.TVector = New TVector
Global Acc.TVector = New TVector ; Akkumulator

Graphics(800, 600, 0, 2)
SetBuffer(BackBuffer())

For t# = 0.0 To 10.0 Step 0.01 ; [s]
	If KeyDown(1) Then Exit
	
	Local u# = ImpactDuration*(t - ImpactDuration)*Heaviside(t - ImpactDuration)
	Local v# =  (ImpactDuration^2.0 - t^2.0)/2.0*Heaviside(t - ImpactDuration)
	Local w# = -t^2.0/2.0
	
	ScaleVector(Acc, ImpactForce, (u + v + w)/Mass)
	CopyVector(Position, Acc)

	
	ScaleVector(Acc, GravityForce, t^2/(2.0*Mass))
	AddVector(Position, Position, Acc)
	
	ScaleVector(Acc, Velocity0, t)
	AddVector(Position, Position, Acc)
	
	AddVector(Position, Position, Position0)


	Cls()
	DrawGround()
	Color(255, 0, 255)
	DrawVector(Position0)
	If t < ImpactDuration Then
		Color(0, 255, 255)
	Else
		Color(255, 255, 255)
	EndIf
	DrawVector(Position)
	
	Color(255, 255, 255)
	Text(10, 10, "t = " + t + " s")
	Text(10, 25, "r.x = " + Position\X + " m")
	Text(10, 40, "r.y = " + Position\Y + " m")
	Flip()
	
	If Position\Y <= 0.0 Then Exit
Next

WaitKey()
End

Function Heaviside#(x#)
	If x < 0.0 Then
		Return 0.0
	Else If x >= 0.0 Then
		Return 1.0
	EndIf
End Function

Function DrawGround()
	Line(0, GRAPHICS_Y_OFFSET, GraphicsWidth() - 1, GRAPHICS_Y_OFFSET)
End Function