;/////////////////////////////////////////////////////////////////////////////////////////////////
;
;                              M a d e  b y  K r y a n                                   30.03.´04
;
;/////////////////////////////////////////////////////////////////////////////////////////////////

Type texture
 Field image
 Field status$
 Field texid
End Type

Graphics3D 800,600,16
; eine Textur mit CreateTexture erstellen
cubetexture=CreateTexture(100,100)
;die textur einfrieren, notwendig um in den texturbuffer umzuschalten
LockTexture cubetexture
; den buffer auf den texturebuffer umstellen
SetBuffer TextureBuffer(cubetexture)
;irgendwas in die textur malen
Color 255,255,255
Rect 0,0,100,100
Color 255,0,0
Oval 0,0,100,100
Color 0,0,255
Oval 25,25,50,50
Color 0,255,0
Line 0,0,100,100
;zurück zum backbuffer
SetBuffer BackBuffer()
;texture wieder entfrieren, notwendig für ActivatedTexture
UnlockTexture cubetexture
;ActivatedTexture liefert die aktualisierte Texturid,wird immer neu sein
;ist bei jeder kleinen änderung der textur wichtig, wenn sie aktualsiert werden soll
fertigetexture=ActivatedTexture(cubetexture)
;sonst alles wie gewöhnlich...
cube=CreateCube()
camera=CreateCamera()
light=CreateLight()
PositionEntity cube,0,0,10
EntityTexture cube,fertigetexture

Repeat
TurnEntity cube,1,1,1
UpdateWorld
RenderWorld
Flip
Until KeyHit(1)
End


Function CreateTexture(Xgroesse,Ygroesse)
 obj.texture=New texture
 obj\status$="unlocked"
 obj\image=CreateImage(Xgroesse,Ygroesse)
 SaveImage obj\image,Str$(obj\image)+".bmp"
 Return Handle(obj)
End Function
Function ActivatedTexture(textureid)
 obj.texture=Object.texture(textureid)
 If obj\status$="unlocked" Then 
  If obj\texid<>0 Then FreeTexture obj\texid
  obj\texid=LoadTexture(Str$(obj\image)+".bmp")
 End If
 Return obj\texid
End Function
Function NoTexture(textureid)
 obj.texture=Object.texture(textureid)
 FreeTexture obj\texid
 DeleteFile obj\image+".bmp"
 FreeImage obj\image
 Delete obj
End Function
Function LockTexture(textureid)
 obj.texture=Object.texture(textureid)
 obj\status$="locked"
End Function
Function UnlockTexture(textureid)
 obj.texture=Object.texture(textureid)
 obj\status$="unlocked"
 SaveImage obj\image,Str$(obj\image)+".bmp"
End Function
Function TextureBuffer(textureid)
 obj.texture=Object.texture(textureid)
 If obj\status$="locked" Then
  Return ImageBuffer(obj\image)
 Else
  Return GraphicsBuffer()
 End If
End Function
Function DrawTexture(textureid,x,y)
 obj.texture=Object.texture(textureid)
 DrawImage obj\image,x,y
End Function