;SuperText-Function
;Written by Kekskiller

Graphics 640,480,16,1
SetBuffer BackBuffer()
SeedRnd 1
ClsColor 255,255,255

Global rectx[10],recty[10],rectw[10],recth[10],rectr[10],rectg[10],rectb[10]
For z=1 To 10
 rectx[z]=Int(Rnd(60,GraphicsWidth()-60))
 recty[z]=Int(Rnd(60,GraphicsHeight()-60))
 rectw[z]=Int(Rnd(10,50)):recth[z]=Int(Rnd(10,50))
 rectr[z]=Int(Rnd(50,180))
 rectg[z]=Int(Rnd(50,180))
 rectb[z]=Int(Rnd(50,180))
Next

Repeat
Cls
mx=MouseX()
my=MouseY()
For z=1 To 10
 Color rectr[z],rectg[z],rectb[z]
 Rect rectx[z],recty[z],rectw[z],recth[z],1
Next
SuperText(10,5,"Engine-Test",255,255,255,0,0,0,$555555,0,0,1,1,6,3)
SuperText(10,25,"This is a simple Sample.",215,215,255,0,0,0,$555599,0,0,1,1,6,3)
SuperText(10,45,"Use mouse to move the colored Panel.",215,255,215,0,0,0,$559955,0,0,1,1,6,3)
SuperText(mx,my,"Mousex: "+mx+"  Mousey: "+my,255,255,255,0,0,0,$555555,0,0,1,1,6,3)
Flip
Until KeyHit(1)
End

Function SuperText(x,y,msg$,froR,froG,froB,fraR,fraG,fraB,shadowcolor,centerx=0,centery=0,framewidth=0,shadow=0,shadowfw=3,shadowfh=3)
If shadow=1 Then
 buf=GraphicsBuffer()
 gfxw=GraphicsWidth()-1
 gfxh=GraphicsHeight()-1
 msgw=StringWidth(msg$)+shadowfw*2
 msgh=StringHeight(msg$)+shadowfh*2
 If centerx=1 Then xminus=-msgw/2 Else xminus=-shadowfw
 If centery=1 Then yminus=-msgh/2 Else yminus=-shadowfh
 LockBuffer
 For zx=1 To msgw
  For zy=1 To msgh
   px=(x+xminus)+zx:py=(y+yminus)+zy
   If px>=0 And py>=0 And px<=gfxw And py<=gfxh Then
    rgbbefore=ReadPixelFast(px,py,buf)
    rgbfinish=((rgbbefore And $FEFEFE)+(shadowcolor And $FEFEFE))/2
    WritePixelFast px,py,rgbfinish,buf
   EndIf
  Next
 Next
 UnlockBuffer
EndIf
If framewidth>0 Then
For zx=-framewidth To framewidth
 For zy=-framewidth To framewidth
  Color fraR,fraG,fraB
  If framewidth<>0 Then Text x+zx,y+zy,msg$,centerx,centery
 Next
Next
EndIf
Color froR,froG,froB
Text x,y,msg$,centerx,centery
End Function