Global DrawPivot, DrawCam, GraphicsX, GraphicsY, CurrFont.TFont3D, LastDrawn.TImageClass3D, DrawZ#, AutoMidH = False
Global PrimitiveMesh, PrimitiveSurf, OriginX#, OriginY#
Global DrawR = 255, DrawG = 255, DrawB = 255, DrawA# = 1
Global CameraCount, Cameras[ 64 ]

Type TImageClass3D
	Field Path$
	Field TextureH
	Field Width
	Field Height
	Field TexWidth
	Field TexHeight
	Field Mesh
	Field Surface
	Field HandleX#
	Field HandleY#
	Field Rotation#
	Field ScaleX#
	Field ScaleY#
	
	Field FWidth
	Field FHeight
	Field FStart
	Field FCount
	Field FramesPerRow
	Field FramesPerColumn
	Field Animated
End Type

Type TFont3D
	Field ImageClass.TImageClass3D
	Field CharWidth[ 255 ]
	Field Height
End Type

Function Init3D( Is3D = False )
	GraphicsX = GraphicsWidth()
	GraphicsY = GraphicsHeight()
	
	DrawCam = CreateCamera()
	CameraProjMode DrawCam, 2
	CameraZoom DrawCam, 2/Float( GraphicsX )
	CameraRange DrawCam, 1, 1001
	If Is3D Then
		CameraProjMode DrawCam, 0
		CameraClsMode DrawCam, False, True
	EndIf
	
	DrawPivot = CreatePivot( DrawCam )
	TurnEntity DrawPivot, 180, 0, 0
	PositionEntity DrawPivot, -GraphicsX/2., GraphicsY/2., 1000, True
	
	If Is3D Then PositionEntity DrawCam, -5000, -5000, -5000
	
	PrimitiveMesh = CreateMesh( DrawPivot )
	EntityFX PrimitiveMesh, 1 + 2 + 16
	PrimitiveSurf = CreateSurface( PrimitiveMesh )
	
	SetFont3D LoadFont3D( "", 15 )
End Function

Function LoadImage3D.TImageClass3D( Path$, AlphaEnabled = False, Flag = 4 )
	ImageClass.TImageClass3D = New TImageClass3D
	
	PrepareTexture( ImageClass, Path$, Flag )
	
	If ImageClass\TextureH Then
		ImageClass\Path$ = Path$
		ImageClass\FWidth = ImageClass\Width
		ImageClass\FHeight = ImageClass\Height
		ImageClass\TexWidth = TextureWidth( ImageClass\TextureH )
		ImageClass\TexHeight = TextureHeight( ImageClass\TextureH )
		ImageClass\FramesPerRow = 1
		ImageClass\FramesPerColumn = 1
		ImageClass\Mesh = CreateMesh( DrawPivot )
		ImageClass\Surface = CreateSurface( ImageClass\Mesh )
		ImageClass\ScaleX# = 1
		ImageClass\ScaleY# = 1
		
		EntityTexture ImageClass\Mesh, ImageClass\TextureH
		EntityFX ImageClass\Mesh, 1 + 2 + 16 + 32*AlphaEnabled
		
		If AutoMidH Then MidHandle3D ImageClass
		
		Return ImageClass
	Else
		RuntimeError "Texture " + Path$ + " doesn't exist"
	EndIf
End Function

Function LoadAnimImage3D.TImageClass3D( Path$, FWidth, FHeight, FFirst, FCount, AlphaEnabled = False, Flag = 4 )
	ImageClass.TImageClass3D = New TImageClass3D
	
	PrepareTexture( ImageClass, Path$, Flag )
	
	If ImageClass\TextureH Then
		ImageClass\Path$ = Path$
		ImageClass\FWidth = FWidth
		ImageClass\FHeight = FHeight
		ImageClass\TexWidth = TextureWidth( ImageClass\TextureH )
		ImageClass\TexHeight = TextureHeight( ImageClass\TextureH )
		ImageClass\Mesh = CreateMesh( DrawPivot )
		ImageClass\Surface = CreateSurface( ImageClass\Mesh )
		ImageClass\FCount = FCount
		ImageClass\FramesPerRow = Floor( ImageClass\Width/Float( FWidth ) )
		ImageClass\FramesPerColumn = Floor( ImageClass\Height/Float( FHeight ) )
		ImageClass\Animated = True
		ImageClass\ScaleX# = 1
		ImageClass\ScaleY# = 1
		
		EntityTexture ImageClass\Mesh, ImageClass\TextureH, 0
		EntityFX ImageClass\Mesh, 1 + 2 + 16 + 32*AlphaEnabled
		
		If AutoMidH Then MidHandle3D ImageClass
		
		Return ImageClass
	Else
		RuntimeError "Texture " + Path$ + " doesn't exist"
	EndIf
End Function

Function LoadFont3D.TFont3D( Path$, Height = 12, Bold = False, Italic = False, Underline = False, AlphaEnabled = False, Flags = 4 )
	Font.TFont3D = New TFont3D
	
	FontH = LoadFont( Path$, Height, Bold, Italic, Underline )
	SetFont FontH
	
	For i = 0 To 255
		Font\CharWidth[ i ] = StringWidth( Chr( i ) )
	Next
	
	Font\Height = FontHeight()
	
	Image = CreateImage( 512, 512 )
	SetBuffer ImageBuffer( Image )
	
	For i = 0 To 255
		X = ( i Mod 16 )*32
		Y = Floor( i/16. )*32
		Text X, Y, Chr( i )
	Next
	
	SetBuffer BackBuffer()
	
	Add = MilliSecs() Mod 100
	SaveImage Image, "__Temp" + Add + ".bmp"
	Font\ImageClass = LoadAnimImage3D( "__Temp" + Add + ".bmp", 32, 32, 0, 256, AlphaEnabled, Flags )
	HandleImage3D Font\ImageClass, 0, 0
	DeleteFile "__Temp" + Add + ".bmp"
	FreeImage Image
	
	FreeFont FontH
	
	Return Font
End Function

Function SetFont3D( Font.TFont3D )
	CurrFont = Font
End Function

Function FontHeight3D()
	Return CurrFont\Height
End Function

Function Text3D( X#, Y#, SourceString$, CenteredX = False, CenteredY = False )
	X# = X# - Int( CenteredX*StringWidth3D( SourceString$ )*0.5 )
	Y# = Y# - Int( CenteredY*FontHeight3D()*0.5 )
	
	Local DrawX# = X#
	For i = 1 To Len( SourceString$ )
		DrawImage3D CurrFont\ImageClass, DrawX#, Y#, Asc( Mid( SourceString$, i, 1 ) )
		DrawX# = DrawX# + CurrFont\CharWidth[ Asc( Mid( SourceString$, i, 1 ) ) ]
	Next
End Function

Global piep:String = "Hallo"

eier=eier+1
Print "Hans hat "+eieranzahl+" Eier!"