; -----------------------
; TEXTFIELDS
; BY OZZI789 - 20.12.2012
; -----------------------



;GFX INITIALIZATION
Graphics 640,480
SetBuffer BackBuffer()
timer = CreateTimer (60) 

;GET RANDOM NUMBERS
SeedRnd MilliSecs()
;WE NEED THIS FLAG LATER
Global set_next_active=0

;THE TYPE WE STORE OUR TEXTFIELDS
Type textfield
	Field id
	Field x
	Field y
	Field active
	Field content$
End Type 


;CREATE 3 TEXTFIELDS
i.textfield= New textfield
	i\id=1
	i\x=400
	i\y=360
	i\active=1

i.textfield= New textfield
	i\id=2
	i\x=500
	i\y=420
	i\active=0
	
	
i.textfield= New textfield
	i\id=3
	i\x=380
	i\y=0
	i\active=0



;MAINLOOOP
While Not KeyHit(1)
	Cls 
	;RENDER TEXTFIELDS
	render_textfield()
	;GET INPUT FOR TEXTFIELDS VIA GETKEY()
	get_input()
	;RENDER RANDOM STUFF TO SHOW "MULTITASKING"
	Color Rnd(0,255),Rnd(0,255),Rnd(0,255)
	Rect Rnd(0,320),Rand(0,320),20,20,Rnd(0,1)	
	Color 255,255,255
	Rect 0,0,340,340,0
	;WAITTIMER AND RENDER SCREEN
	WaitTimer timer 
	Flip 0
Wend 


;HERE WE GET THE KEYBOARD INPUT
Function get_input()
	For i.textfield = Each textfield
		;IF THE FLAG WAS SET, SET NEXT INSTANCE IN TYPE COLLECTION ACTIVE
		If set_next_active=1
			;RESET THE FLAG
			set_next_active=0
			i\active=1
		EndIf
		;IF WE GOT THE ACTIVE FIELD
		If i\active=1
			;GET INPUT
			temp_key=GetKey()
			;IF THERE WAS A INPUT
			If temp_key<>0
				Select temp_key
					Case 8 ;BACKSPACE -> DELETE LAST CHAR
						i\content$=Left(i\content$,Len(i\content$)-1)
					Case 9 ;TAB CHANGE TO NEXT TEXTFIELD
						i\active=0
						set_next_active=1
					Case 13 ;ENTER WAS PRESSED -> DO WHAT YOU WANT WITH IT
						DebugLog "Enter pressed in textfield with id# "+i\id
					Default ;NONE OF THE ABOVE CASES -> ADD PRESSED KEY
						i\content$=i\content$+Chr(temp_key)
				End Select 
			EndIf 
		EndIf 
	Next
End Function 


Function render_textfield()
	For i.textfield = Each textfield
		If i\active=1 ;RENDER THE ACTIVE ONES
			Color 255,255,255
			Rect i\x,i\y,200,20,0
			Text i\x+2,i\y,i\content$
		Else ;RENDER THE INACTIVE ONES
			Color 255,0,0
			Rect i\x,i\y,200,20,0
			Text i\x+2,i\y,i\content$
		EndIf 
	Next
End Function