Graphics(512,256,32,2)

;* Bild Laden:
Local img = LoadImage("ToSW.png")

;* Schwarzweiß Version erzeugen:
Local img_sw = KonvertiereZuSW(img)

;* Bilder zum Vergleich anzeigen:
DrawImage(img,0,0)
DrawImage(img_sw,256,0)

WaitKey()
End

Function KonvertiereZuSW(img)
    Local breit = ImageWidth(img)
    Local hoch = ImageHeight(img)
    ;* Bild Kopieren um das Ursprungsbild nicht zu verändern:
    Local New_img = CopyImage(img)
    
    ;* X,Y Koordinaten für das Bild
    ;* Alpha, Rot, Grün, Blau Farbbestandteile
    ;* ARGB Farb-Summe
    Local x,y, a,r,g,b, argb
    
    ;* Den Buffer des Bildes zum Bearbeiten auswählen:
    SetBuffer(ImageBuffer(New_img))
    ;* Buffer Sichern um schnellen Zugriff mittels Read/Write-PixelFast zu haben
    LockBuffer(ImageBuffer(New_img))
    
    ;* alle Pixel des Bildes durchgehen:
    For y = 0 To hoch-1
        For x = 0 To breit-1
            ;* Einlesen der Pixelfarbe:
            argb = ReadPixelFast(x,y)
            
            ;* Zerlegen der Farbe in ihre Bestandteile:
            a = (argb And $FF000000)/$1000000 
            r = (argb And $FF0000)/$10000 
            g = (argb And $FF00)/$100 
            b = argb And $FF 
            
            ;* Mittelwert der Farbe:
            Local sw = (r+g+b)/3
            
            ;* Farbe wieder zusammensetzen, Alpha-Kanal bleibt unverändert
            argb = a*$1000000 + sw*$10000 + sw*$100 + sw
            
            ;* Pixelfarbe Schreiben:
            WritePixelFast(x,y,argb)
        Next
    Next
    ;* Buffer wieder Freigeben:
    UnlockBuffer(ImageBuffer(New_img))
    ;* Buffer wieder zurückschalten, damit es keine Probleme mit den 
    ;* Folgenden Zeichenbefehlen gibt.
    SetBuffer(FrontBuffer())
    
    ;* Das Fertig bearbeitete Bild zurückliefern:
    Return New_img
End Function

Function greyFilter( src )
	Local width = ImageWidth(src)
	Local height = ImageHeight(src)
	
	Local out = CreateImage(width, height)
	
	Local col
	Local r
	Local g
	Local b
	Local grey
	
	Local srcBuffer = ImageBuffer(src)
	Local outBuffer = ImageBuffer(out)
	
	LockBuffer( srcBuffer )
	LockBuffer( outBuffer )
	
	For x = 0 To width -1
		For y = 0 To height -1
			col = ReadPixelFast( x, y, srcBuffer )
			
			r = (col And $FF0000)/$10000
			g = (col And $FF00	)/$100
			b = (col And $FF	)
			
			grey = (r + g + b) /3.
			
			col = grey *$10000 + grey *$100 + grey
			
			WritePixelFast( x, y, col, outBuffer )
		Next
	Next
	
	UnlockBuffer( srcBuffer )
	UnlockBuffer( outBuffer )
	
	Return out
End Function

ReadPixel

Writepixel

ReadPixelFast

WritePixelFast

LockBuffer

Graphics 1024,768,0,2 ;Fenster erstellen
AppTitle "Graustufenumwandler" ;Anwedungsname
Local Colored = LoadImage("tosw.png") ; Laden des Bildes
Local Greyscaled = GreyscaleImg(Colored) ;Bild durch Aufruf der Funktion in Graustufen umwandeln

DrawImage Colored,192,256 ;Ursprüngliches, farbiges Bild zeichnen
DrawImage Greyscaled,576,256 ;"Schwarz-Weißes" Bild zeichen

WaitKey()
End

Function GreyscaleImg(Img)
	Local Image = CopyImage(Img) ;Kopieren des ursprünglichen Bilds
	Local TempAlpha   ;
	Local TempRed      ;   
	Local TempGreen     ;
	Local TempBlue      ; Variablen deklarieren
	Local GreyColor    ;
	Local TempRGBValue;
	LockBuffer ImageBuffer(Image)
	For x = 0 To ImageWidth(Image) - 1 ;Jede Zeile durchgehen
		For y = 0 To ImageHeight(Image) - 1 ; Für die jeweilige Zeile alle Y-Werte durchgehen
			TempRGBValue = ReadPixelFast(x,y,ImageBuffer(Image)) ;Auslesen jedes Pixels
			TempAlpha = (TempRGBValue And $FF000000)/$1000000 ; ':
			TempRed = (TempRGBValue And $FF0000)/$10000        ; :.Umwandeln der Werte in RGB bzw Alpha
			TempGreen = (TempRGBValue And $FF00)/$100          ; :'
			TempBlue = TempRGBValue And $FF                   ;,:
			GreyColor = TempRed*0.3 + TempGreen*0.59 + TempBlue*0.11 ; Bilden des Einzel-Werts für jeden Pixel mit der Leuchtkraftformel für Graustufen.Alternativ könnte man auch einfach den Durchschnittswert bilden
			TempRed = GreyColor   ;
			TempGreen = GreyColor  :; RGB-Werte mit dem Einzel-Wert belegen
			TempBlue = GreyColor  ;
			TempRGBValue = TempAlpha * $1000000 + TempRed * $10000 + TempGreen * $100 + TempBlue ;Wieder zu einem Wert zusammenfügen
			WritePixelFast x,y,TempRGBValue,ImageBuffer(Image) ;Pixel wieder einfärben
		Next
	Next
	UnlockBuffer ImageBuffer(Image)
	Return Image ;Bild wird zurückgegeben
End Function

Graphics3D 800, 600, 0, 2


image = LoadImage("tosw.png")


tex1 = CreateTexture( ImageWidth( image ), ImageHeight( image ) )
tex2 = CreateTexture( ImageWidth( image ), ImageHeight( image ) )


SetBuffer( TextureBuffer( tex2 ) )

DrawImage image, 0, 0

LockBuffer()

For x = 0 To 255
	For y = 0 To 255
		rgb = ReadPixelFast( x, y )
		r = (rgb And $FF0000)/$10000
		g = (rgb And $FF00)/$100
		b = rgb And $FF
		asdf = ( r + g + b ) / 3
		rgb2 = 256*$1000000 + asdf*$10000 + asdf*$100 + asdf 
		WritePixelFast( x, y, rgb2 )
	Next
Next

UnlockBuffer()


SetBuffer( TextureBuffer( tex1 ) )

DrawImage image, 0, 0


SetBuffer BackBuffer()



timer = CreateTimer( 60 )



alpha# = 0.9


camera = CreateCamera()
PositionEntity camera, 0, 0, -4

cube1 = CreateCube()
EntityTexture cube1, tex1
cube2 = CreateCube()
EntityTexture cube2, tex2



Repeat
	
	If alpha > 0 Then alpha = alpha - 0.005
	EntityAlpha cube1, alpha
	
	RenderWorld
	UpdateWorld
	
	WaitTimer timer
	Flip 0
	Cls
	
Until KeyHit( 1 )


End

image = LoadImage("sample.png")


imgHeight 	= ImageHeight(image)
imgWidth	= ImageWidth(image)

Graphics imgWidth*2, imgHeight, 32, 2
SetBuffer BackBuffer()

DrawImage image, 0, 0

LockBuffer BackBuffer()

For y = 0 To imgHeight - 1
	For x = 0 To imgWidth - 1
		rgbValue = ReadPixelFast(x, y)
		
		rValue = (rgbValue And $FF0000)	/ $10000
		gValue = (rgbValue And $FF00)	/ $100
		bValue = (rgbValue And $FF)
		
		bwValue = (rValue + gValue + bValue) / 3
		
		newValue = 255 * $1000000 + bwValue * $10000 + bwValue * $100 + bwValue
		
		WritePixelFast(x + imgWidth, y, newValue)
						
	Next
Next

UnlockBuffer BackBuffer()
Flip

WaitKey:End	

Graphics 600,300,0,2
SetBuffer BackBuffer()


Local infile.TImage=LoadMyImage("tosw.png")
Local outfile.TImage=Color2SW(infile,Null)
SaveMyImage(outfile,"bnw.bmp")
DrawImage infile\hwnd,0,0
DrawImage outfile\hwnd,258,0

Flip
WaitKey
End


Type TImage
	Field width%,height%
	Field hwnd%,buff%
End Type


Function CreateMyImage.TImage(width%,height%)
	Local image.TImage=New TImage
	image\hwnd=CreateImage(width,height)
	If image\hwnd=0 Then RuntimeError "Bild nicht gefunden!"
	image\buff=ImageBuffer(image\hwnd)
	image\width=width
	image\height=height
	Return image.TImage
End Function
Function LoadMyImage.TImage(filename$)
	Local image.TImage=New TImage
	image\hwnd=LoadImage(filename)
	If image\hwnd=0 Then RuntimeError "Bild nicht gefunden!"
	image\buff=ImageBuffer(image\hwnd)
	image\width=ImageWidth(image\hwnd)
	image\height=ImageHeight(image\hwnd)
	Return image.TImage
End Function
Function Color2SW.TImage(src.TImage,dst.TImage)
	If src.TImage=Null Then RuntimeError "Bild nicht gefunden!"
	If dst.TImage=Null Then dst.TImage=CreateMyImage(src\width,src\height)
	LockBuffer src\buff
	LockBuffer dst\buff
	For y=0 To src\height-1
		For x=0 To src\width-1
			Local argb=ReadPixelFast(x,y,src\buff)
			Local a = (argb And $FF000000)/$1000000 
			Local r = (argb And $FF0000)/$10000 
			Local g = (argb And $FF00)/$100 
			Local b = argb And $FF 
			Local rgb=(r+g+b)/3
			argb = a*$1000000 + rgb*$10000 + rgb*$100 + rgb 
			WritePixelFast(x,y,argb,dst\buff)
		Next
	Next
	
	UnlockBuffer src\buff
	UnlockBuffer dst\buff
	Return dst.TImage
	
End Function
Function SaveMyImage(src.TImage,filename$)
	If src.TImage=Null Then RuntimeError "Bild nicht gefunden!"
	SaveImage(src\hwnd,filename)
End Function