Const gfx = 800
Const gfy = 600

Graphics gfx,gfy,32,1

SeedRnd MilliSecs()

AutoMidHandle True 

Type partikel
	Field x#,y#
	Field winkel
	Field speed
	Field rgb
End Type

Type image 
	Field x,y ;x,y koordinaten
	Field time_left ;ablaufende Zeit
	Field time ;allgemein: time = millisecs()
	Field pic_nr ;zufallsnummer, wodurch das zu nutzende image gewählt wird
	Field image ;image des bildes
	Field width,height
End Type 

Global FPSSEC = MilliSecs(), FPS, FRAMES ;alles um FPS anzuzeigen
Global anz ;zeigt später die aktuelle Partikelanzahl an    

SetBuffer BackBuffer()

Repeat
Cls
HidePointer() ;mauscursor weg machen :)

Different()
UpdateImages()
UpdatePartikel()
FPS()

Flip 
Until KeyHit(1):End 

Function NewImage(x#,y#)
	
	imgwidth = Rand(20,50)
	imgheight = Rand(20,50)

	circle = CreateImage(imgwidth,imgheight)
	SetBuffer ImageBuffer(circle)
	Color Rand(100,255),Rand(100,255),Rand(100,255)
	Oval 0,0,imgwidth,imgheight
	
	cube = CreateImage(imgwidth,imgheight)
	SetBuffer ImageBuffer(cube)
	Color Rand(100,255),Rand(100,255),Rand(100,255)
	Rect 0,0,imgwidth,imgheight
	
	i.image = New image
	i\x = x#
	i\y = y# 
	i\time_left = Rand(2,5)
	i\time = MilliSecs()
	i\pic_nr = Rand(1,2)
	
	Select i\pic_nr
		Case 1
			i\image = circle
		Case 2
			i\image = cube
	End Select 
	
	i\width = ImageWidth(i\image)
	i\height = ImageHeight(i\image)

	SetBuffer BackBuffer() ;jup, wieder in den alten buffer wechseln, sonst sind wir noch im imagebuffer
	
End Function 	

Function UpdateImages()
For i.image = Each image
	DrawImage i\image,i\x,i\y
	Color 255,255,255
	Text i\x-i\width/2,i\y-i\height,"Zeit: "+i\time_left ;ablaufende zeit wird angezeigt
	
	If MilliSecs()-1000 => i\time
		i\time = MilliSecs()
		i\time_left = i\time_left - 1 ;immer eine Sekunde abziehen
	EndIf 
	
	If i\time_left <= 0
		CreatePartikel(i\x,i\y,i\width,i\height)
		Delete i.image
	EndIf 	
Next
End Function 	

Function CreatePartikel(x#,y#,breite,hoehe)
LockBuffer BackBuffer()
	For i = x#-(breite/2) To x#+breite Step 3 ;bei verschiedenen größen des bildes am step rumspielen
		For j = y#-(hoehe/2) To y#+hoehe Step 3
			rgb = ReadPixelFast(i,j)
			If rgb <> 0 
				p.partikel = New partikel
				p\x = i
				p\y = j
				p\winkel = Rnd(-180,180)
				p\speed = Rand(5,10)
				p\rgb = rgb
				anz = anz + 1
			EndIf 
		Next 
	Next 
UnlockBuffer BackBuffer()
End Function 		

Function UpdatePartikel()
For p.partikel = Each partikel

	LockBuffer BackBuffer()
		WritePixelFast p\x,p\y,p\rgb
	UnlockBuffer BackBuffer()
	
	p\x = p\x - Cos(p\winkel)*p\speed
	p\y = p\y - Sin(p\winkel)*p\speed
	
	If p\x < 0 Or p\x > (gfx-1) Or p\y < 0 Or p\y > (gfy-1) ;eventuelles sauber machen :)
		Delete p.partikel
		anz = anz - 1
	EndIf 
	
Next 
End Function 	

Function FPS()
frames = frames + 1
	If MilliSecs() - fpssec => 1000 Then
		fps = frames
		frames = 0
		fpssec = MilliSecs()
	EndIf
Return FPS	
End Function 

Function Different()
	mx# = MouseX()
	my# = MouseY()

	Color 255,255,0
	Plot mx#,my#
	
	Text mx#-65,my#+10,"Click to set image"

	If MouseHit(1)
		NewImage(mx#,my#)
	EndIf 

	Color 255,255,0
	Text 0,0,"Frames per Second: "+FPS()
	Text 0,15,"Aktuelle Partikelanzahl: "+anz
End Function 			

For p.partikel = Each partikel 

   LockBuffer BackBuffer() 
      WritePixelFast p\x,p\y,p\rgb 
   UnlockBuffer BackBuffer()