Graphics3D 640,480,16,2
SetBuffer BackBuffer()

;globale Variablen
Global gCamera            ;unsere Kamera
Global gLight             ;unser Licht
Global gShip              ;unser Schiff
Global gSkyBox            ;unsere SkyBox, also der Hintergrund
Global gSkyBoxTexture     ;die Textur dazu
Global gShipXPos#   = 0.0
Global gShipYPos#   = 0.0
Global gShipZPos#   = 0.0
Global gShipPitch#  = 0.0
Global gShipYaw#    = 0.0
Global gShipRoll#   = 0.0
Global gShipThrust# = 0.0 ;aktueller Schub
Global gShipVel#    = 0.0 ;aktuelle Geschwindigkeit

Const MOUSE_SENSITIVITY# = 0.1  ;Mausempfindlichkeit
Const SHIP_MAX_THRUST#   = 0.05 ;maximaler Schub
Const SHIP_MAX_VEL#      = 1.0  ;maximale Geschwindigkeit
Const SHIP_FRICTION#     = 0.95 ;\"Reibung\"

;Initialisierungen
Init()


While Not KeyHit(1)

  ;relative Mausverschiebung holen
  msx# = MouseXSpeed()
  msy# = MouseYSpeed()
  
  ;wir rotieren um die X-Achse (Pitch) und die Y-Achse (Yaw)
  gShipPitch = msy * MOUSE_SENSITIVITY
  gShipYaw = -msx * MOUSE_SENSITIVITY
  TurnEntity( gShip, gShipPitch, gShipYaw, gShipRoll )

  ;natürlich soll sich unser Schiff auch bewegen
  ;wir geben mit der linken Maustaste Schub nach vorn
  If( MouseDown(1) )
    gShipThrust = SHIP_MAX_THRUST
  Else
    gShipThrust = 0.0
  End If
  ;neue Geschwindigkeit berechnen
  gShipVel = gShipVel + gShipThrust
  ;Das Schiff soll langsam wieder abbremsen (\"Reibung\"), wenn kein Schub vorhanden ist
  gShipVel = gShipVel * SHIP_FRICTION
  ;Maximale Geschwindigkeit erreicht?
  If( gShipVel > SHIP_MAX_VEL )
    gShipVel = SHIP_MAX_VEL
  End If
  
  ;Nun müssen wir den Geschwindigkeitsvektor, der immer in Z-Richtung wirkt,
  ;in das globale Koordinatensystem umrechnen
  TFormVector( 0, 0, gShipVel, 0, 0 )
  ;Schiff bewegen
  MoveEntity( gShip, TFormedX(), TFormedY(), TFormedZ() )
  ;Die Skybox bewegen wir mit...
  PositionEntity( gSkyBox, EntityX( gShip ), EntityY( gShip ), EntityZ( gShip ) )

  UpdateWorld()
  RenderWorld()

  Render2dOverlay()
  RenderHud()
  
  ;wir halten die Maus immer in der Mitte, damit sie nicht aus dem Fenster \"rauswandert\"
  MoveMouse( GraphicsWidth() / 2, GraphicsHeight() / 2 )

  Flip
Wend
End

;Initialisiert das Spiel
Function Init()
  ;Wir verstecken den Mauszeiger
  HidePointer()
  ;Unser Schiff...
  gShip = CreatePivot()
  ;Kamera initialisieren, wir \"hängen\" sie an das Schiff
  gCamera = CreateCamera( gShip )
  ;Es werde Licht... ein ungerichtetes Punktlicht, das wir an die Kamera hängen
  gLight = CreateLight(2)
  EntityParent( gLight, gCamera )
  ;SkyBox erzeugen
  gSkyBox = CreateCube()
  ScaleEntity( gSkyBox, 500, 500, 500 )
  ;Wir wollen diesen SkyBox-Würfel von innen sehen, deshalb kehren wir die Sichtbarkeit
  ;der Dreiecke um
  FlipMesh( gSkyBox )
  ;Jetzt erzeugen wir eine Textur, die einen simplen Sternenhintergrund darstellt
  gSkyBoxTexture = CreateTexture( 256, 256 )
  ;Wir erzeugen ein paar zufällige (weiße) Sterne
  SetBuffer TextureBuffer( gSkyBoxTexture )
  LockBuffer TextureBuffer( gSkyBoxTexture )
  For i = 1 To 1000
    WritePixelFast( Rnd( 256 ), Rnd( 256 ), $FFFFFF, TextureBuffer( gSkyBoxTexture ) )
  Next
  UnlockBuffer TextureBuffer( gSkyBoxTexture )
  SetBuffer BackBuffer()
  EntityTexture( gSkyBox, gSkyBoxTexture )
  ;Jetzt erzeugen wir noch ein paar Objekte (Kugeln), damit die Bewegung sichtbar wird
  For i = 1 To 200
    s = CreateSphere()
    PositionEntity( s, Rnd( -300, 300 ), Rnd( -300, 300 ), Rnd( -300, 300 ) )
  Next
End Function

;Zeichnet das Head Up Display
Function RenderHud()
  xResolution% = GraphicsWidth()
  yResolution% = GraphicsHeight()
  xCenter% = xResolution / 2
  yCenter% = yResolution / 2
  ;Wir zeichnen das Fadenkreuz genau in die Mitte, in grün 
  Color( 0, 255, 0 )
  Line( xCenter, yCenter, xCenter + 10, yCenter      )
  Line( xCenter, yCenter, xCenter - 10, yCenter      )
  Line( xCenter, yCenter, xCenter     , yCenter + 10 )
  Line( xCenter, yCenter, xCenter     , yCenter - 10 )
End Function

;Zeichnet alle 2d-Elemente (Text) außer das HUD
Function Render2dOverlay()
  Text 10, 10, \"X: \" + EntityX( gShip )
  Text 10, 30, \"Y: \" + EntityY( gShip )
  Text 10, 50, \"Z: \" + EntityZ( gShip )
  Text 10, 90, \"Pitch: \" + EntityPitch( gShip )
  Text 10, 110, \"Yaw: \" + EntityYaw( gShip )
  Text 10, 130, \"Roll: \" + EntityRoll( gShip )
End Function