Graphics 800,600,0,2
SetBuffer BackBuffer()

Global HScore#
Menu()

Function Menu()
	Local Timer, Sel, txt$[2], STime, Phase#
	
	txt[0]="Spielen"
	txt[1]="Highscores"
	txt[2]="Ende"
	
	Sel=0
	
	STime=MilliSecs()
	Timer=CreateTimer(60)
	While Not KeyHit(1)
		
		Sel=(Sel+KeyHit(208)-KeyHit(200)+3) Mod 3
		
		Phase=Phase+Sin((MilliSecs()-STime)*0.3)*0.75
		For i=0 To 2
			Text 400-Len(txt[i])*4,200-6+i*100,txt[i]
			
			If Sel=i
				Box(400-Len(txt[i])*4-24-Phase,200-6+i*100-24-Phase,Len(txt[i])*8+40+Phase*2,48+Phase*2)
			Else
				Box(400-Len(txt[i])*4-24,200-6+i*100-24,Len(txt[i])*8+40,48)
			EndIf
		Next
		
		If KeyHit(57) Or KeyHit(28)
			Select Sel
				Case 0
					Main()
					Return
				Case 1
					;ignore :>
				Case 2
					End
			End Select
		EndIf
		
		Flip 0
		
		WaitTimer(Timer)
		
		Cls
	Wend
End Function

Function Main()
	Local Timer, Px#, Py#, f, scrollX#, fTime, Vy#, Vx#, Actual.Building, Following.Building, FFollowing.Building, B.Building, Started, VMax#, Dist#, Txt$, Phase#, Bi.Bird, STime, jEngaged, jAllowed
	
	Delete Each Bird
	Delete Each Building
	SeedRnd(MilliSecs())
	
	Started=False
	f=0
	Dist=0
	VMax=5
	
	Px=50
	Py=400
	
	Vy=0
	
	scrollX=0
	
	Actual.Building=newBuilding(0,100,900)
	Following.Building=newBuilding(1100,150,500)
	FFollowing=Null
	
	STime=MilliSecs()
	Timer=CreateTimer(60)
	While Not KeyHit(1)
		
		If Px>Following\xStart+Following\width*0.5
			Delete Actual
			Actual=Following
			Following=FFollowing
			FFollowing=Null
		EndIf
		If FFollowing=Null
			FFollowing=newBuilding(Following\xStart+Following\width+Rand(50,225), Rand(Min(Max(Following\height-150,50),550),Following\height+100), Rand(350,600))
			
			If Rand(1,5)=1
				For x=FFollowing\xStart+8 To FFollowing\xStart+FFollowing\width-8 Step 32
					newBird(x,600-FFollowing\height-8)
				Next
			EndIf
		EndIf
		
		drawPlayer(Px-scrollX,Py,f)
		drawLandscape(scrollX)
		
		Vy=Vy+0.1
		For B=Each Building
			If RectsOverlap(Px-8-scrollX,Py+32,24,4 , B\xStart-scrollX,600-B\height,B\width+8,12)
				If Py<600-B\height
					If jump
						jump=False
					Else
						Vy=0
						Py=600-B\height-34
					EndIf
				EndIf
			Else
				If RectsOverlap(Px-8-scrollX,Py,24,36 , B\xStart-scrollX,600-B\height+8,8,B\height) Or RectsOverlap(Px-8-scrollX,Py,24,36 , B\xStart-scrollX+B\width,600-B\height+8,8,B\height)
					Vx=0
					
					If Vy<0
						Vy=0
					EndIf
				EndIf
			EndIf
		Next
		
		For Bi=Each Bird
			If Bi\vy=0
				If Abs(Px-Bi\x)<32 And Abs(Py-Bi\y)<64
					Bi\vx=Rnd(-2.00,2.00)
					Bi\vy=Rnd(-1.00,-2.50)
				EndIf
			EndIf
			
			
			Bi\x=Bi\x+Bi\vx
			Bi\y=Bi\y+Bi\vy
			drawBird(Bi, scrollX)
			
			If Bi\x-scrollX<0
				Delete Bi
			Else
				If Bi\y<0
					Delete Bi
				EndIf
			EndIf
		Next
		
		Px=Px+Vx
		Py=Py+Vy
		
		If Px>100
			scrollX=scrollX+Vx
		EndIf
		Dist=Dist+Vx/10
		VMax=Max(5,Int(Dist/150))
		
		If Started
			If MilliSecs()-fTime>100
				f=(f+1) Mod 8
				fTime=MilliSecs()
			EndIf
			
			If Vx<5
				Vx=Vx+0.1
			Else
				Vx=Vx+0.0075
			EndIf
			If Vx>VMax
				Vx=VMax
			EndIf
			
			If Not jump
				If KeyDown(200)
					jAllowed=False
					For B.Building=Each Building
						If Px-4>B\xStart And Px+4<B\xStart+B\width
							jAllowed=True
						EndIf
					Next
					
					If jAllowed
						jTime=MilliSecs()
						jEngaged=True
						
						jump=True
						Vy=-1
					EndIf
				EndIf
			EndIf
			
			If jEngaged
				If MilliSecs()-jTime>250
					jEngaged=False
				EndIf
				
				If Not KeyDown(200)
					jEngaged=False
				EndIf
				
				Vy=Vy-0.3
				
				If Vy<-4
					Vy=-4
					jEngaged=False
				EndIf
			EndIf
		Else
			Phase=Phase+Sin((MilliSecs()-STime)*0.3)*0.75
			
			Txt="Highscore: "+Int(HScore)
			Text 400-Len(Txt)*4,300,Txt
			
			Box(400-Len(Txt)*4-26-Phase,300-24-Phase,26+Len(Txt)*8+18+Phase*2,48+Phase*2)
			
			Txt$="Press Space to start"
			Text 400-Len(Txt$)*4,400,Txt
			
			If KeyHit(57)
				Started=True
			EndIf
		EndIf
		
		FPS=FPS+1
		If MilliSecs()-FPSTime>999
			FPSCur=FPS
			FPS=0
			FPSTime=MilliSecs()
		EndIf
		Text 775,575,fpscur
		
		Flip 0
		
		WaitTimer(Timer)
		
		Cls
		
		If Py>575
			HScore=Dist
			Main()
			Return
		EndIf
	Wend
	
	Menu()
End Function

Type Building
	Field xStart
	Field height
	Field width
End Type

Function newBuilding.Building(x, h, w)
	Local B.Building
	
	B=New Building
	B\xStart=x
	B\height=h
	B\width=w
	
	Return B
End Function

Function Box(x, y, w, h)
	For xi=x To x+w Step 8
		Text xi,y,"-"
		Text xi,y+h,"-"
	Next
	For yi=y To y+h Step 8
		Text x,yi,"|"
		Text x+w,yi,"|"
	Next
End Function

Function drawPlayer(x, y, f)
	Select f
		Case 0
			Text x,y,"O"
			Text x-8,y+12,"/|\"
			Text x-4,y+24,"||"
		Case 1
			Text x,y,"O"
			Text x-8,y+12,"/|>"
			Text x-4,y+24,"|\"
		Case 2
			Text x,y,"O"
			Text x-8,y+12,"/|>"
			Text x-2,y+24,"\\"
		Case 3
			Text x,y,"O"
			Text x-8,y+12,"/|>"
			Text x-4,y+24,"|\"
		Case 4
			Text x,y,"O"
			Text x-8,y+12,"/|\"
			Text x-4,y+24,"||"
		Case 5
			Text x,y,"O"
			Text x-8,y+12,"<|\"
			Text x-4,y+24,"/|"
		Case 6
			Text x,y,"O"
			Text x-8,y+12,"<|\"
			Text x-6,y+24,"//"
		Case 7
			Text x,y,"O"
			Text x-8,y+12,"<|\"
			Text x-4,y+24,"/|"
	End Select
End Function

Function drawLandscape(scrollX#)
	Local B.Building
	
	For B=Each Building
		For i=B\xStart-scrollX To B\xStart-scrollX+B\width Step 8
			Text i,600-B\height,"*"
		Next
		For i=600 To 600-B\height Step -8
			Text B\xStart-scrollX,i,"*"
			Text B\xStart-scrollX+B\width,i,"*"
		Next
	Next
End Function

Function Max#(A#, B#)
	If A>B
		Return A
	Else
		Return B
	EndIf
End Function

Function Min#(A#, B#)
	If A<B
		Return A
	Else
		Return B
	EndIf
End Function

Type Bird
	Field x#
	Field y#
	
	Field vx#
	Field vy#
	
	Field f
	Field fTime
End Type

Function newBird.Bird(x, y)
	Local B.Bird
	
	B=New Bird
	
	B\x=x
	B\y=y
	
	Return B
End Function

Function drawBird(B.Bird, scrollX#)
	Select B\f
		Case 0
			Text B\x-scrollX-4,B\y,"\/"
		Case 1
			Text B\x-scrollX-4,B\y,"/\"
	End Select
	
	If B\vy<0
		If MilliSecs()-B\fTime>100
			B\f=1-B\f
			B\fTime=MilliSecs()
		EndIf
	EndIf
End Function