;SingleSurface Trails
Const TrailVertexes = 100
Global TInterval
Global TPiv, ViewCam
Global TBox1
Global TBox2

Type Trails
	Field Parent
	Field Mesh, Surf, Size#
	Field X#[TrailVertexes], Y#[TrailVertexes], Z#[TrailVertexes]
	Field Interval, R[TrailVertexes], G[TrailVertexes], B[TrailVertexes]
End Type

Function InitTrail(Cam)
	TPiv = CreatePivot():ViewCam = Cam
	TBox1 = CreateCube(TPiv):MoveEntity TBox1, 0, 5, 0:ScaleEntity TBox1, .1, .1, .1
	TBox2 = CreateCube(TPiv):MoveEntity TBox2, 0,-5, 0:ScaleEntity TBox2, .1, .1, .1
End Function

Function AddTrail(Texture, Parent, Size#, Interval)
	Local T.Trails = New Trails, TempBrush, TCount
	TempBrush = CreateBrush(255, 255, 255):BrushTexture TempBrush, Texture:BrushFX TempBrush, 19
	T\Mesh = CreateMesh():T\Surf = CreateSurface(T\Mesh, TempBrush)
	FreeBrush TempBrush
	T\Parent = Parent:T\Interval = Interval:T\Size = Size
	For TCount = 0 To TrailVertexes
		T\X[TCount] = EntityX(T\Parent):T\Y[TCount] = EntityY(T\Parent):T\Z[TCount] = EntityZ(T\Parent)
		T\R[TCount] = 255:T\G[TCount] = 255:T\B[TCount] = 255
	Next
	Return Handle(T.Trails)
End Function

Function RemoveTrail(Trail)
	Local T.Trails = Object.Trails(Trail)
	FreeEntity T\Mesh:Delete T.Trails
End Function

Function ColorTrail(Trail, R, G, B)
	Local T.Trails = Object.Trails(Trail)
	T\R[0] = R:T\G[0] = G:T\B[0] = B
End Function

Function UpdateTrails(Came)
	Local T.Trails, Cur, V1[3], Pos#[5], Multi#, Dist#, LDist#
	TInterval = TInterval + 1
	For T = Each Trails
		T\X[0] = EntityX(T\Parent,1):T\Y[0] = EntityY(T\Parent,1):T\Z[0] = EntityZ(T\Parent,1)
		If (TInterval Mod T\Interval) = 0
			For Cur = TrailVertexes To 1 Step -1
				T\X[Cur] = T\X[Cur-1]:T\Y[Cur] = T\Y[Cur-1]:T\Z[Cur] = T\Z[Cur-1]
				T\R[Cur] = T\R[Cur-1]:T\G[Cur] = T\G[Cur-1]:T\B[Cur] = T\B[Cur-1]
			Next
		EndIf
		ClearSurface T\Surf
		
		V1[0] = AddVertex(T\Surf, T\X[TrailVertexes], T\Y[TrailVertexes], T\Z[TrailVertexes], 0, 0):VertexColor T\Surf, V1[0], T\R[Cur], T\G[Cur], T\B[Cur]
		V1[1] = AddVertex(T\Surf, T\X[TrailVertexes], T\Y[TrailVertexes], T\Z[TrailVertexes], 1, 0):VertexColor T\Surf, V1[1], T\R[Cur], T\G[Cur], T\B[Cur]
		For Cur = TrailVertexes-1 To 0 Step -1
			LDist = Dist:Dist = Abs(Sqr((T\X[Cur+1]-T\X[Cur])^2.0 + (T\Y[Cur+1]-T\Y[Cur])^2.0 + (T\Z[Cur+1]-T\Z[Cur])^2.0)):Multi = 1-(Cur/Float(TrailVertexes))
			
			PositionEntity TPiv, T\X[Cur], T\Y[Cur], T\Z[Cur], 1
			PositionEntity TBox1, 0, -T\Size*Multi, 0
			PositionEntity TBox2, 0,  T\Size*Multi, 0
			PointEntity TPiv, ViewCam, 1
			
			Pos[0] = EntityX(TBox1, 1):Pos[1] = EntityY(TBox1, 1):Pos[2] = EntityZ(TBox1, 1)
			Pos[3] = EntityX(TBox2, 1):Pos[4] = EntityY(TBox2, 1):Pos[5] = EntityZ(TBox2, 1)
			
			V1[2] = AddVertex(T\Surf, Pos[0], Pos[1], Pos[2], 0, LDist# + Dist + Cur):VertexColor T\Surf, V1[2], T\R[Cur], T\G[Cur], T\B[Cur]
			V1[3] = AddVertex(T\Surf, Pos[3], Pos[4], Pos[5], 1, LDist# + Dist + Cur):VertexColor T\Surf, V1[3], T\R[Cur], T\G[Cur], T\B[Cur]
			
			AddTriangle T\Surf, V1[0], V1[1], V1[2]
			AddTriangle T\Surf, V1[2], V1[1], V1[3]
			
			V1[0] = V1[2]:V1[1] = V1[3]
		Next
	Next
End Function

;trailsystem test
Graphics3D 1024, 768, 32, 2
Include "TrailSystem.bb"
SeedRnd MilliSecs()

Piv = CreatePivot()
Box = CreateCone():ScaleEntity box, .2, .2, .2
Camera = CreateCamera(Piv):PositionEntity Camera, 0, 0,-25, 1
Texture = LoadTexture("texture.png", 2)
InitTrail(Camera):CameraZoom Camera, 2
WireFrame 0
trail = AddTrail(Texture ,Box, 1, 1)

r = 20
While Not KeyHit(1)
	Cls
	
	
	If KeyDown(28)
		PositionEntity Box, Sin(a*4)*90, Cos(a)*r, Sin(a)*r
		a = a + 1
	EndIf
	;RotateEntity Piv, EntityPitch(Piv)+MouseYSpeed(), EntityYaw(Piv)-MouseXSpeed(), 0
	;MoveMouse 512, 384
	PointEntity Piv, Box
	
	UpdateTrails(Camera)
	ColorTrail(trail, r2, g2, b2)
	r2 = r2 + 25
	If r2 > 255
		g2 = g2 + 25
		r2 = 0
		If g2 > 255
			b2 = b2 + 25
			g2 = 0
			If b2 > 255
				b2 = 0
			EndIf
		EndIf
	EndIf
	
	RenderWorld
	
	Flip
Wend