;Reflexionstype
Type Reflection

	Field camera
	
	Field tex
	
	Field entity, re
	
	Field update,time, ur

End Type


;Erstellt eine neue Reflexion. Parameter:
;entity: Das Entity, das die Reflexion bekommen soll
;cam: Normalerweise die Spielerkamera, andere Objekte sind auch möglich
;tex_size: Die Texturgröße (am Besten zwischen 128x128 und 1024x1024)
;update: Die Zeit zwischen 2 Updates (je größer, desto schneller läuft das Programm)
Function CreateReflection(entity, cam, tex_size,update=10)

	rf.Reflection = New Reflection
	
	rf\entity = cam
	
	rf\re = entity
	
	rf\camera = CreateCamera()
	
	rf\tex = CreateTexture(tex_size,tex_size,1 + 128 + 256) 
	
	rf\update = update
	
	rf\ur = 1
	
	EntityTexture entity,rf\tex

End Function


;Entfernt die Reflexion von einem Entity. Parameter:
;entity: Ein Entity mit Reflexion
;new_tex: Handle der neuen Textur. Ist dieser Parameter 0, wird eine weiße Textur verwendet, ist er -1 wird keine neue Textur verwendet
Function RemoveReflection(entity, new_tex = -1)

	For rf.Reflection = Each Reflection
	
		If rf\re = entity
		
			FreeEntity rf\camera
			
			FreeTexture rf\tex
			
			If new_tex > 0
			
				EntityTexture entity,new_tex
				
			ElseIf new_tex = 0
			
				white_tex = CreateTexture(1,1)

				WritePixel 0,0,$FFFFFF,TextureBuffer(white_tex)
				
				EntityTexture entity,white_tex
				
				FreeTexture white_tex
			
			EndIf
			
			Delete rf
			
			Exit
			
		EndIf
	
	Next

End Function


;Schaltet das Updaten der Reflexion eines Entities aus oder ein. Parameter:
;entity: Entity mit Reflexion
;update: Update ein- oder ausschalten (1/0)
Function ReflectionState(entity,update)

	For rf.Reflection = Each Reflection
	
		If rf\re = entity
		
			rf\ur = update
			
			Exit
		
		EndIf
	
	Next

End Function


;Diese Funktion aktualisiert alle Reflexionen. Sie sollte in der Hauptschleife aufgerufen werden.
Function UpdateReflections() 

	For rf.Reflection = Each Reflection
	
		If MilliSecs()-rf\time > rf\update And rf\ur = 1 And EntityInView(rf\re,rf\entity)

			tex_sz = TextureWidth(rf\tex) 
			
			ShowEntity rf\camera 
			HideEntity rf\entity 
			PositionEntity rf\camera, EntityX#(rf\entity), EntityY#(rf\entity), EntityZ#(rf\entity) 
			CameraClsMode rf\camera, False, True 
			CameraViewport rf\camera, 0, 0, tex_sz, tex_sz 
			
			SetCubeFace rf\tex, 0 
			RotateEntity rf\camera, 0, 90, 0 
			RenderWorld 
			CopyRect 0, 0, tex_sz, tex_sz, 0, 0, BackBuffer(), TextureBuffer(rf\tex) 
			
			SetCubeFace rf\tex, 1 
			RotateEntity rf\camera, 0, 0, 0 
			RenderWorld 
			CopyRect 0, 0, tex_sz, tex_sz, 0, 0, BackBuffer(), TextureBuffer(rf\tex) 
			
			SetCubeFace rf\tex, 2 
			RotateEntity rf\camera, 0, - 90, 0 
			RenderWorld 
			CopyRect 0, 0, tex_sz, tex_sz, 0, 0, BackBuffer(), TextureBuffer(rf\tex) 
			
			SetCubeFace rf\tex, 3 
			RotateEntity rf\camera, 0, 180, 0 
			RenderWorld 
			CopyRect 0, 0, tex_sz, tex_sz, 0, 0, BackBuffer(), TextureBuffer(rf\tex) 
			
			SetCubeFace rf\tex, 4 
			RotateEntity rf\camera, - 90, 0, 0 
			RenderWorld 
			CopyRect 0, 0, tex_sz, tex_sz, 0, 0, BackBuffer(), TextureBuffer(rf\tex) 
			
			SetCubeFace rf\tex, 5 
			RotateEntity rf\camera, 90, 0, 0 
			RenderWorld 
			CopyRect 0, 0, tex_sz, tex_sz, 0, 0, BackBuffer(), TextureBuffer(rf\tex) 
			
			ShowEntity rf\entity 
			HideEntity rf\camera 
		
			rf\time = MilliSecs()
		
		EndIf
			
	Next	
	
End Function 

SeedRnd(MilliSecs())

Graphics3D 1680,1050,32,1


cam = CreateCamera() 

PositionEntity cam, 0, 10, - 10 


light = CreateLight() 

RotateEntity light, 90, 0, 0 


prim1 = LoadMesh("teapot.x")

PositionEntity prim1, 0, 10, 0 

ScaleEntity prim1,3,3,3

EntityFX prim1,1

CreateReflection(prim1, cam, 128, 10)

reflect_update = 1

factor = 7


ground = CreatePlane() 

EntityColor ground,103,140,50

ground_tex = LoadTexture("mountain.jpg")

ScaleTexture ground_tex, 10, 10 

EntityTexture ground, ground_tex
 

sky = CreateSphere(16) 

ScaleEntity sky, 500, 500, 500 

FlipMesh sky 

EntityFX sky, 1 

sky_tex = LoadTexture("sky2.jpg")

EntityTexture sky, sky_tex



test_obj1 = CreateCylinder()

FitMesh test_obj1, - 10, 0, - 10, 5,9,7

EntityColor test_obj1, 255,200,0

test_obj2 = CreateCone()

FitMesh test_obj2, 10, 0, 10, 6, 7, 8 

EntityColor test_obj2,100,150,255

test_piv = CreatePivot() 

PositionEntity test_piv, 0, 15, 0 

test_obj3 = CreateSphere(16,test_piv)

ScaleEntity test_obj3,1,0.2,1

PositionEntity test_obj3, 0, 0, 10 


SetBuffer BackBuffer() 

timer = CreateTimer(60)

Color 0,0,0


While Not KeyDown(1) 

	
	mxs# = mxs# + (MouseXSpeed() / 5.0) 
	
	mys# = mys# + (MouseYSpeed() / 5.0) 

	RotateEntity cam, mys#, - mxs#, 0 
	
	MoveMouse GraphicsWidth()/2,GraphicsHeight()/2


	If KeyDown(17) MoveEntity cam, 0, 0, 0.6
	
	If KeyDown(31) MoveEntity cam, 0, 0, -0.6
	
	If KeyDown(32) MoveEntity cam, 0.6, 0, 0 
	
	If KeyDown(30) MoveEntity cam, -0.6, 0, 0 
	
	If KeyHit(200) 
	
		If factor < 10 factor = factor + 1
		
		RemoveReflection(prim1)
		
		CreateReflection(prim1, cam, 2^factor, 10)
	
	EndIf
	
	If KeyHit(208) 
	
		If factor > 0 factor = factor - 1
		
		RemoveReflection(prim1)
		
		CreateReflection(prim1, cam, 2^factor, 10)
	
	EndIf
	
	If KeyHit(57) reflect_update = 1-reflect_update: ReflectionState(prim1, reflect_update)
	
	
	TurnEntity prim1,0,1,0
	
	TurnEntity test_piv, 0, 2, 0
	
	 
	UpdateReflections()
	
	RenderWorld 
	
	
	PositionEntity sky,EntityX(cam),0,EntityZ(cam)
	
	tsz = 2^factor
	
        ;FPS-Anzeige von hectic
	ms=MilliSecs():Text 0,0,"FPS: "+fps+" | Texturauflösung: "+tsz+"x"+tsz
	If ms>mt mt=ms+502:fps=frame:frame=0 Else frame=frame+2 
	
		 
	Flip 0

	
	If Not KeyDown(29) WaitTimer(timer)
	

Wend 


End