Konverter für B3D-Files

Übersicht Ressourcen Andere Programme oder Tools

Neue Antwort erstellen

 

sddsmhr

Betreff: Konverter für B3D-Files

BeitragMo, März 19, 2012 2:12
Antworten mit Zitat
Benutzer-Profile anzeigen
Es ist doch etwas erstaunlich, dass nach etlichen Jahren offenbar immer noch kein vernünftiger (!) Konverter für b3d-Files existiert.

Ist das so gewollt? Oder habe ich etwas verpasst?

Der einzige mir bekannte Konverter ist BiTurn und der funktioniert irgendwie nur in Ausnahmefällen. Neutral

Nachtrag: ggf. verschieben in "Ressourcen->Andere Programme oder Tools".
  • Zuletzt bearbeitet von sddsmhr am Mo, März 19, 2012 2:54, insgesamt einmal bearbeitet

Tankbuster

BeitragMo, März 19, 2012 2:19
Antworten mit Zitat
Benutzer-Profile anzeigen
Es gibt ein exportscript für Blender. Ob es mit der neusten Blender-Version funktioniert, ist allerdings fraglich.

Siehe:
https://www.blitzforum.de/foru...856#400856
Twitter
Download Jewel Snake!
Windows|Android
 

sddsmhr

BeitragMo, März 19, 2012 2:58
Antworten mit Zitat
Benutzer-Profile anzeigen
Nein, nein, nein... Ich habe ein B3D-File vorliegen und möchte es woanders importieren, genauer in MilkShape3D. Wink

Xeres

Moderator

BeitragMo, März 19, 2012 2:59
Antworten mit Zitat
Benutzer-Profile anzeigen
~VERSCHOBEN~

Dieser Thread passte nicht in das Forum, in dem er ursprünglich gepostet wurde.
Win10 Prof.(x64)/Ubuntu 16.04|CPU 4x3Ghz (Intel i5-4590S)|RAM 8 GB|GeForce GTX 960
Wie man Fragen richtig stellt || "Es geht nicht" || Video-Tutorial: Sinus & Cosinus
T
HERE IS NO FAIR. THERE IS NO JUSTICE. THERE IS JUST ME. (Death, Discworld)

Chester

BeitragMo, März 19, 2012 14:17
Antworten mit Zitat
Benutzer-Profile anzeigen
Lade die Datei in B3D und exportier es in 3DS, das du in Milkshape importieren kannst.

Exportscript von hier:
BlitzBasic: [AUSKLAPPEN]
;Save Mesh 3DS, on 26/9/06

Graphics3D 640,480,0,2
AppTitle "Save Mesh 3DS"
SetBuffer BackBuffer()

camera=CreateCamera() ;init world
light=CreateLight()
RotateEntity light,45,45,0

tex=MakeTestTexture(128,128) ;new texture

shape=0 ;type of shape to save
Select shape
Case 0
mesh1=CreateCube() : child1=CreateCube(mesh1)
PositionEntity child1,1,-1,1 : RotateEntity child1,30,-30,30
Case 1
mesh1=CreateSphere(8) : child1=CreateSphere(8,mesh1)
PositionEntity child1,1,1,-1
Case 2
mesh1=CreateCylinder(8,True) : child1=CreateCylinder(8,True,mesh1)
PositionEntity child1,1,1,1 : RotateEntity child1,30,30,-30
Case 3
mesh1=CreateCone(8,True) : child1=CreateCone(8,True,mesh1)
PositionEntity child1,1,-1,-1
Case 4
mesh1=LoadMesh("yourname.x")
Case 5
mesh1=LoadAnimMesh("yourname.x")
End Select
EntityTexture mesh1,tex ;texture
If child1 Then EntityTexture child1,tex

filename$="test.3ds" ;save to 3ds file
;texfile$="test.bmp" ;optional texture filename
ok=SaveMesh3DS(mesh1,filename$,texfile$)

mesh2=LoadMesh(filename$) ;load new 3ds
If Len(texfile$)=0 Then EntityTexture mesh2,tex ;texture

PositionEntity mesh1,-2,0,5 ;position to left
PositionEntity mesh2,2,0,5 ;position to right

While Not KeyHit(1)
RenderWorld()

TurnEntity mesh1,0.3,0.2,0.1
TurnEntity mesh2,0.3,0.2,0.1

If KeyHit(17) Then wf=Not wf : WireFrame wf ;W key

Text 0,0,"ok="+ok+" filename$="+filename$

Flip
Wend

Function SaveMesh3DS(mesh,filename$,texfile$="",diffuse=$CCCCCC)
;Saves a given mesh, or mesh hierarchy, as a 3DS file
;From "3dsinfo.txt" by Jochen Wilhelmy
;mesh=mesh/mesh hierarchy handle, filename$="name.3ds"
;texfile$=optional texture file, diffuse=optional diffuse color

Local file,piv,matname$,mnlen,tflen,ent,surf,si,mi,objname$,onlen
Local tssize,tmsize,tfsize,tosize,tcsize,tvsize,otsize
Local eobjsize,ematsize,editsize,i

file=WriteFile(filename$)
If Not file Return False ;fail code
piv=CreatePivot() ;pivot to tform vertices

;calculate chunk sizes and file size
matname$="Material"
mnlen=Len(matname$)+1
tflen=Len(texfile$)+1
ent=mesh
While ent
For si=1 To CountSurfaces(ent)
surf=GetSurface(ent,si)
mi=mi+1 : If mi<10 Then objname$="mesh0"+mi Else objname$="mesh"+mi
onlen=Len(objname$)+1
tssize=6+(CountTriangles(surf)*4) ;sizeof(Tri_Smooth)
tmsize=8+mnlen+(CountTriangles(surf)*2) ;sizeof(Tri_Material)
tfsize=8+(CountTriangles(surf)*4*2)+tmsize+tssize ;sizeof(Tri_FaceList)
tosize=8+(CountVertices(surf)*2) ;sizeof(Tri_VertexOptions)
tcsize=8+(CountVertices(surf)*2*4) ;sizeof(Tri_MappingCoords)
tvsize=8+(CountVertices(surf)*3*4) ;sizeof(Tri_VertexList)
otsize=6+tvsize+tcsize+tosize+54+tfsize ;sizeof(Object_TriMesh)
eobjsize=eobjsize+(6+onlen+otsize) ;sizeof(All_Edit_Objects)
Next
ent=NextChild(ent)
Wend
ematsize=6+(6+mnlen)+(15*3)+(14*6)+10 ;sizeof(Edit_Material)
If tflen>1 Then ematsize=ematsize+(6+(6+tflen)) ;Mat_TextureMap1
editsize=6+10+ematsize+10+eobjsize ;sizeof(Edit3DS)

;Main3DS Chunk
WriteShort file,$4D4D ;wChunkID, Main3DS
WriteInt file,6+10+editsize ;dwChunkSize, filesize
;Version3DS Chunk
WriteShort file,$0002 ;wChunkID, Version3DS
WriteInt file,10 ;dwChunkSize, sizeof(Version3DS)
WriteInt file,3 ;ChunkData, dwVersion3DS

;Edit3DS Chunk, Main3DS Subchunk
WriteShort file,$3D3D ;wChunkID, Edit3DS
WriteInt file,editsize ;dwChunkSize, editsize=6+ematsize+eobjsize
;Edit_MeshVersion, Edit3DS Subchunk
WriteShort file,$3D3E ;wChunkID, Edit_MeshVersion
WriteInt file,10 ;dwChunkSize, sizeof(Edit_MeshVersion)
WriteInt file,3 ;ChunkData, dwMeshVersion

;Edit_Material Chunk, Edit3DS Subchunk
WriteShort file,$AFFF ;wChunkID, Edit_Material
WriteInt file,ematsize ;dwChunkSize, ematsize=6+(6+mnlen)+(15*3)
;Mat_Name01 Chunk, Edit_Material Subchunk
WriteShort file,$A000 ;wChunkID, Mat_Name01
WriteInt file,6+mnlen ;dwChunkSize, sizeof(Mat_Name01)
WriteStringAscii(file,matname$) ;ChunkData, material name
WriteByte file,0 ;ChunkData, Ascii-z null byte
;Mat_Ambient Chunk, Edit_Material Subchunk
WriteShort file,$A010 ;wChunkID, Mat_Ambient
WriteInt file,15 ;dwChunkSize, sizeof(Mat_Ambient)
WriteShort file,$0011 ;wChunkID, bRGB
WriteInt file,9 ;dwChunkSize, sizeof(bRGB)
WriteRGBColor(file,$666666) ;ChunkData, ambient color
;Mat_Diffuse Chunk, Edit_Material Subchunk
WriteShort file,$A020 ;wChunkID, Mat_Diffuse
WriteInt file,15 ;dwChunkSize, sizeof(Mat_Diffuse)
WriteShort file,$0011 ;wChunkID, bRGB
WriteInt file,9 ;dwChunkSize, sizeof(bRGB)
WriteRGBColor(file,diffuse) ;ChunkData, diffuse color
;Mat_Specular Chunk, Edit_Material Subchunk
WriteShort file,$A030 ;wChunkID, Mat_Specular
WriteInt file,15 ;dwChunkSize, sizeof(Mat_Specular)
WriteShort file,$0011 ;wChunkID, bRGB
WriteInt file,9 ;dwChunkSize, sizeof(bRGB)
WriteRGBColor(file,$FFFFFF) ;ChunkData, specular color
;Mat_Shininess Chunk, Edit_Material Subchunk
WriteShort file,$A040 ;wChunkID, Mat_Shininess
WriteInt file,14 ;dwChunkSize, sizeof(Mat_Shininess)
WriteShort file,$0030 ;wChunkID, wPercent
WriteInt file,8 ;dwChunkSize, sizeof(wPercent)
WriteShort file,75 ;ChunkData, Shininess
;Mat_ShininessStrength Chunk, Edit_Material Subchunk
WriteShort file,$A041 ;wChunkID, Mat_ShininessStrength
WriteInt file,14 ;dwChunkSize, sizeof(Mat_ShininessStrength)
WriteShort file,$0030 ;wChunkID, wPercent
WriteInt file,8 ;dwChunkSize, sizeof(wPercent)
WriteShort file,20 ;ChunkData, ShininessStrength
;Mat_Transparency Chunk, Edit_Material Subchunk
WriteShort file,$A050 ;wChunkID, Mat_Transparency
WriteInt file,14 ;dwChunkSize, sizeof(Mat_Transparency)
WriteShort file,$0030 ;wChunkID, wPercent
WriteInt file,8 ;dwChunkSize, sizeof(wPercent)
WriteShort file,0 ;ChunkData, Transparency
;Mat_TransparencyFalloff Chunk, Edit_Material Subchunk
WriteShort file,$A052 ;wChunkID, Mat_TransparencyFalloff
WriteInt file,14 ;dwChunkSize, sizeof(Mat_TransparencyFalloff)
WriteShort file,$0030 ;wChunkID, wPercent
WriteInt file,8 ;dwChunkSize, sizeof(wPercent)
WriteShort file,0 ;ChunkData, TransparencyFalloff
;Mat_ReflectionBlur Chunk, Edit_Material Subchunk
WriteShort file,$A053 ;wChunkID, Mat_ReflectionBlur
WriteInt file,14 ;dwChunkSize, sizeof(Mat_ReflectionBlur)
WriteShort file,$0030 ;wChunkID, wPercent
WriteInt file,8 ;dwChunkSize, sizeof(wPercent)
WriteShort file,0 ;ChunkData, ReflectionBlur
;Mat_SelfIllumination Chunk, Edit_Material Subchunk
WriteShort file,$A084 ;wChunkID, Mat_SelfIllumination
WriteInt file,14 ;dwChunkSize, sizeof(Mat_SelfIllumination)
WriteShort file,$0030 ;wChunkID, wPercent
WriteInt file,8 ;dwChunkSize, sizeof(wPercent)
WriteShort file,0 ;ChunkData, SelfIllumination
;Edit_WireThickness Chunk, Edit_Material Subchunk
WriteShort file,$A087 ;wChunkID, Edit_WireThickness
WriteInt file,10 ;dwChunkSize, sizeof(Edit_WireThickness)
WriteFloat file,1 ;fWireThickness
;Mat_TextureMap1 Chunk, Edit_Material Subchunk
If tflen>1
WriteShort file,$A200 ;wChunkID, Mat_TextureMap1
WriteInt file,6+(6+tflen) ;dwChunkSize, sizeof(Mat_TextureMap1)
;Mat_TextureFilename, Mat_TextureMap1 Subchunk
WriteShort file,$A300 ;wChunkID, Mat_TextureFilename
WriteInt file,6+tflen ;dwChunkSize, sizeof(Mat_TextureFilename)
WriteStringAscii(file,texfile$) ;ChunkData, texture filename
WriteByte file,0 ;ChunkData, Ascii-z null byte
EndIf

;Edit_OneUnit Chunk, Edit3DS Subchunk
WriteShort file,$0100 ;wChunkID, Edit_OneUnit
WriteInt file,10 ;dwChunkSize, sizeof(Edit_OneUnit)
WriteFloat file,1 ;fOneUnit

;calculate each mesh object chunk sizes
ent=mesh : mi=0
While ent
For si=1 To CountSurfaces(ent)
surf=GetSurface(ent,si)
mi=mi+1 : If mi<10 Then objname$="mesh0"+mi Else objname$="mesh"+mi
onlen=Len(objname$)+1
tssize=6+(CountTriangles(surf)*4) ;sizeof(Tri_Smooth)
tmsize=8+mnlen+(CountTriangles(surf)*2) ;sizeof(Tri_Material)
tfsize=8+(CountTriangles(surf)*4*2)+tmsize+tssize ;sizeof(Tri_FaceList)
tosize=8+(CountVertices(surf)*2) ;sizeof(Tri_VertexOptions)
tcsize=8+(CountVertices(surf)*2*4) ;sizeof(Tri_MappingCoords)
tvsize=8+(CountVertices(surf)*3*4) ;sizeof(Tri_VertexList)
otsize=6+tvsize+tcsize+tosize+54+tfsize ;sizeof(Object_TriMesh)
eobjsize=6+onlen+otsize ;sizeof(Edit_Object)
;position/rotate pivot to tform surface vertices
PositionEntity piv,EntityX(ent,1),EntityY(ent,1),EntityZ(ent,1),1
RotateEntity piv,EntityPitch(ent,1),EntityYaw(ent,1),EntityRoll(ent,1),1

;Edit_Object Chunk, Edit3DS Subchunk
WriteShort file,$4000 ;wChunkID, Edit_Object
WriteInt file,eobjsize ;dwChunkSize, eobjsize=6+onlen+otsize
WriteStringAscii(file,objname$) ;ChunkData, object name
WriteByte file,0 ;ChunkData, Ascii-z null byte

;Object_TriMesh Chunk, Edit_Object Subchunk
WriteShort file,$4100 ;wChunkID, Object_TriMesh
WriteInt file,otsize ;dwChunkSize, otsize=6+tvsize+tcsize+54+tfsize
;Tri_VertexList Chunk, Object_TriMesh Subchunk
WriteShort file,$4110 ;wChunkID, Tri_VertexList
WriteInt file,tvsize ;dwChunkSize, tvsize=8+(nVerts*3*4)
WriteShort file,CountVertices(surf) ;ChunkData, wVerticesTotal
For i=0 To CountVertices(surf)-1 ;switch y and z axis
TFormPoint VertexX(surf,i),VertexY(surf,i),VertexZ(surf,i),piv,0
WriteFloat file,TFormedX() ;fVertexX
WriteFloat file,TFormedZ() ;fVertexY
WriteFloat file,TFormedY() ;fVertexZ
Next
;Tri_MappingCoords Chunk, Object_TriMesh Subchunk
WriteShort file,$4140 ;wChunkID, Tri_MappingCoords
WriteInt file,tcsize ;dwChunkSize, tcsize=8+(nVerts*2*4)
WriteShort file,CountVertices(surf) ;ChunkData, wVerticesTotal
For i=0 To CountVertices(surf)-1 ;invert v coord
WriteFloat file,VertexU(surf,i) ;fVertexU
WriteFloat file,-VertexV(surf,i) ;fVertexV
Next
;Tri_VertexOptions Chunk, Object_TriMesh Subchunk
WriteShort file,$4111 ;wChunkID, Tri_VertexOptions
WriteInt file,tosize ;dwChunkSize, tosize=8+(nVerts*2)
WriteShort file,CountVertices(surf) ;ChunkData, wVerticesTotal
For i=0 To CountVertices(surf)-1 ;invert v coord
WriteShort file,$0700 ;AllVertexOptions
Next
;Tri_Local Chunk, Object_TriMesh Subchunk
WriteShort file,$4160 ;wChunkID, Tri_Local
WriteInt file,54 ;dwChunkSize, sizeof(Tri_Local)
For i=0 To 3 ;X,Y,Z,Origin
If i=0 Then WriteFloat file,1 Else WriteFloat file,0 ;fLocal1
If i=1 Then WriteFloat file,1 Else WriteFloat file,0 ;fLocal2
If i=2 Then WriteFloat file,1 Else WriteFloat file,0 ;fLocal3
Next
;Tri_FaceList Chunk, Object_TriMesh Subchunk
WriteShort file,$4120 ;wChunkID, Tri_FaceList
WriteInt file,tfsize ;dwChunkSize, tfsize=8+(nTris*4*2)+tmsize+tssize
WriteShort file,CountTriangles(surf) ;ChunkData, wTrianglesTotal
For i=0 To CountTriangles(surf)-1 ;invert face order
WriteShort file,TriangleVertex(surf,i,2) ;wTriangleVertexA
WriteShort file,TriangleVertex(surf,i,1) ;wTriangleVertexB
WriteShort file,TriangleVertex(surf,i,0) ;wTriangleVertexC
WriteShort file,$0407 ;wFaceFlags
Next
;Tri_Material Chunk, Tri_FaceList Subchunk
WriteShort file,$4130 ;wChunkID, Tri_Material
WriteInt file,tmsize ;dwChunkSize, tmsize=8+mnlen+(nTris*2)
WriteStringAscii(file,matname$) ;ChunkData, material name
WriteByte file,0 ;ChunkData, Ascii-z null byte
WriteShort file,CountTriangles(surf) ;ChunkData, wTrianglesAssigned
For i=0 To CountTriangles(surf)-1
WriteShort file,i ;wTriangleIndex
Next
;Tri_Smooth Chunk, Tri_FaceList Subchunk
WriteShort file,$4150 ;wChunkID, Tri_Smooth
WriteInt file,tssize ;dwChunkSize, tssize=6+(nTris*4)
For i=0 To CountTriangles(surf)-1
WriteInt file,1 ;dwTriangleSmoothGroup
Next

Next
ent=NextChild(ent)
Wend

FreeEntity piv
CloseFile file
Return True ;success code

End Function

Function WriteStringAscii(file,ascii$)
;file=file handle, ascii$=ascii string

Local i,char$
For i=1 To Len(ascii$)
char$=Mid(ascii$,i,1)
WriteByte(file,Asc(char$))
Next

End Function

Function WriteRGBColor(file,rgb)
;file=file handle, rgb=3-byte value

WriteByte(file,(rgb And $FF0000) Shr 16) ;r
WriteByte(file,(rgb And $00FF00) Shr 8) ;g
WriteByte(file,(rgb And $0000FF)) ;b

End Function

Function NextChild(ent)
;Returns next child of entity as if it was on the same hierarchy level
;"NextChild(entity)", by Beaker

If CountChildren(ent)>0
Return GetChild(ent,1)
EndIf
Local foundunused=False
Local foundent=0,parent,sibling
While foundunused=False And ent<>0
parent=GetParent(ent)
If parent<>0
If CountChildren(parent)>1
If GetChild(parent,CountChildren(parent))<>ent
For siblingcnt=1 To CountChildren(parent)
sibling=GetChild(parent,siblingcnt)
If sibling=ent
foundunused=True
foundent=GetChild(parent,siblingcnt+1)
EndIf
Next
EndIf
EndIf
EndIf
ent=parent
Wend
Return foundent

End Function

Function MakeTestTexture(width,height)

Local texture,x,y,rgb
texture=CreateTexture(width,height)
LockBuffer(TextureBuffer(texture))
For y=0 To TextureHeight(texture)-1
For x=0 To TextureWidth(texture)-1
rgb=y+(y*256)+(x*256^2) ;gradient color
WritePixelFast x,y,rgb,TextureBuffer(texture)
Next
Next
UnlockBuffer(TextureBuffer(texture))
SetBuffer TextureBuffer(texture)
Color 255,255,255 : Oval 40,40,30,30
Color 0,0,0 : Text 50,50,"3DS" : Color 255,255,255
SetBuffer BackBuffer()
Return texture

End Function

Amazorn

BeitragMo, März 19, 2012 15:33
Antworten mit Zitat
Benutzer-Profile anzeigen
Es gibt gute Gründe warum man das B3D Format verwendet. Z.b. weil man nicht möchte das sich jemand an den Modellen schadlos hält, diese verändert usw.

BladeRunner

Moderator

BeitragMo, März 19, 2012 16:26
Antworten mit Zitat
Benutzer-Profile anzeigen
Das Argument liesse ich nicht gelten, denn jedes Format kann entschlüsselt und in anderen Programmen verwendet werden Wink
Zu Diensten, Bürger.
Intel T2300, 2.5GB DDR 533, Mobility Radeon X1600 Win XP Home SP3
Intel T8400, 4GB DDR3, Nvidia GF9700M GTS Win 7/64
B3D BMax MaxGUI

Stolzer Gewinner des BAC#48, #52 & #92

Propellator

BeitragMo, März 19, 2012 17:05
Antworten mit Zitat
Benutzer-Profile anzeigen
Tankbuster hat Folgendes geschrieben:
Ob es mit der neusten Blender-Version funktioniert, ist allerdings fraglich.

Tut es nicht, die API von Blender wurde komplett überholt.

Amazorn hat Folgendes geschrieben:
Es gibt gute Gründe warum man das B3D Format verwendet. Z.b. weil man nicht möchte das sich jemand an den Modellen schadlos hält, diese verändert usw.

So oft wie der Zwerg oder der Ninja in der BlitzBasic-Community verwendet wurde, lässt mich an diesem Argument zweifeln. Wink
Propellator - Alles andere ist irrelephant.
Elefanten sind die Könige der Antarktis.

Johannes´

BeitragMo, März 19, 2012 22:05
Antworten mit Zitat
Benutzer-Profile anzeigen
Das Konvertieren sollte sich mit Deled machen lassen. Über entsprechende Plugins ist soweit ich weiß auch das Exportieren direkt für Milkshape möglich. Falls Dein Modell allerdings animiert ist, gibt es Probleme, der b3d - Importer ünterstützt dies meines Wissens nach nicht.
 

sddsmhr

BeitragMo, Apr 02, 2012 19:03
Antworten mit Zitat
Benutzer-Profile anzeigen
Chester hat Folgendes geschrieben:
Lade die Datei in B3D und exportier es in 3DS, das du in Milkshape importieren kannst.

Exportscript [...]

Hm, ja. Das sieht sehr interessant aus...!

Ich denke, das werde ich in der Tat mal testen. Cool

Besten Dank.

Amazorn hat Folgendes geschrieben:
Es gibt gute Gründe warum man das B3D Format verwendet. Z.b. weil man nicht möchte das sich jemand an den Modellen schadlos hält, diese verändert usw.

Neben BladeRunners Argument sehe ich hier auch durchaus eine Innovationsbremse (jemand modelliert ein Rad, und ein anderer will auf Grundlage dieses Rades ein Auto modellieren o.ä.). Mir persönlich kommen gelegentlich auch Modelle unter, die zwar in nichtkommerziellen Projekten weiterverwendet werden dürfen, manchmal aber einfach noch der einen oder anderen Korrektur bedürfen. Das sind dann manchmal sogar nur Kleinigkeiten wie nicht verschweißte Eckpunkte, was dann aber leider im Spiel sofort ins Auge fällt und an und für sich leicht zu korrigieren wäre. Nur leider liegt dann das Modell nur im b3d-Format vor und der Autor ist nicht mehr erreichbar o.ä.

Propellator hat Folgendes geschrieben:
Tut es nicht, die API von Blender wurde komplett überholt.

Diese Erfahrung hatte ich auch gemacht...

Amazorn hat Folgendes geschrieben:
So oft wie der Zwerg oder der Ninja in der BlitzBasic-Community verwendet wurde, lässt mich an diesem Argument zweifeln. Wink

Hehe... waren die nicht von Psionic...?

Die Schildkröte ist auch absolut genial... Cool

Johannes´ hat Folgendes geschrieben:
Das Konvertieren sollte sich mit Deled machen lassen. Über entsprechende Plugins ist soweit ich weiß auch das Exportieren direkt für Milkshape möglich. Falls Dein Modell allerdings animiert ist, gibt es Probleme, der b3d - Importer ünterstützt dies meines Wissens nach nicht.

Hm... Ich hab' nur DeleD Lite (1.81). Dafür bräuchte ich wahrscheinlich die Pro-Version. Aber trotzdem danke für den Tipp erstmal.

Johannes´

BeitragMo, Apr 02, 2012 20:41
Antworten mit Zitat
Benutzer-Profile anzeigen
sddsmhr hat Folgendes geschrieben:
Hm... Ich hab' nur DeleD Lite (1.81). Dafür bräuchte ich wahrscheinlich die Pro-Version.

DeleD ist mittlerweile Opensource.

Amazorn

BeitragMi, Apr 11, 2012 7:24
Antworten mit Zitat
Benutzer-Profile anzeigen
sddsmhr hat Folgendes geschrieben:


Amazorn hat Folgendes geschrieben:
So oft wie der Zwerg oder der Ninja in der BlitzBasic-Community verwendet wurde, lässt mich an diesem Argument zweifeln. Wink

Hehe... waren die nicht von Psionic...?


Das habe ich nicht geschrieben. Bitte pass auf wenn Du zitierst.
Im übrigen sehe ich das mit dem Urheberschutz nicht so locker wie ihr. Ein Rad ist in 2 Minuten modelliert und wer ein Auto modellieren kann hält sich nicht mit der Suche nach Rädern auf.
Das Problem ist, das es viele gibt die sich aus Bruchstücken und Codes ihr Spiel zusammenbasteln und dann als Eigenproduktion ausgeben.
Leider ist die Meinung wenn ich es im Netz finde kann ich es verwenden gerade in dem Bereich extrem verbreitet.
Schaut mal ins Showcase. Stehen da immer die Quellen wo etwas herkommt?

Propellator

BeitragMi, Apr 11, 2012 18:11
Antworten mit Zitat
Benutzer-Profile anzeigen
Das habe ich ebenfalls nicht geschrieben. Bitte pass auf wenn Du zitierst.

Niemand sagte etwas über Urheberrechte etc., wir widerlegten nur deine These dass Leute B3D verwenden würde, damit andere nicht "klauen". Per se ist das blödsinn, da BB-Spiele meistens innerhalb der BB-Community populär sind, und das Hauptargument für B3D ein ganz anderes ist: Es ist das einzige Format, welches Blitz3D richtig unterstützt.
Propellator - Alles andere ist irrelephant.
Elefanten sind die Könige der Antarktis.

Amazorn

BeitragDo, Apr 12, 2012 8:47
Antworten mit Zitat
Benutzer-Profile anzeigen
Propellator hat Folgendes geschrieben:
Das habe ich ebenfalls nicht geschrieben. Bitte pass auf wenn Du zitierst.

Niemand sagte etwas über Urheberrechte etc., wir widerlegten nur deine These dass Leute B3D verwenden würde, damit andere nicht "klauen". Per se ist das blödsinn, da BB-Spiele meistens innerhalb der BB-Community populär sind, und das Hauptargument für B3D ein ganz anderes ist: Es ist das einzige Format, welches Blitz3D richtig unterstützt.


Erst lesen dann schreiben oder hast du einen zweiten Nick mit Namen sddsmhr ?

BladeRunner

Moderator

BeitragDo, Apr 12, 2012 9:50
Antworten mit Zitat
Benutzer-Profile anzeigen
... und jetzt beruhigen wir uns alle wieder und fangen nicht wegen fehlerhaft gesetzter oder verstandener Zitate einen Flamewar an oder der BladeRunner wird ihn mit Close-Napalm beenden.
Danke.
Zu Diensten, Bürger.
Intel T2300, 2.5GB DDR 533, Mobility Radeon X1600 Win XP Home SP3
Intel T8400, 4GB DDR3, Nvidia GF9700M GTS Win 7/64
B3D BMax MaxGUI

Stolzer Gewinner des BAC#48, #52 & #92

Neue Antwort erstellen


Übersicht Ressourcen Andere Programme oder Tools

Gehe zu:

Powered by phpBB © 2001 - 2006, phpBB Group